Unload UserForm Continues Sub

[breynolds0431]

I have a userform (ufRandom) that will show a disclaimer message, which is another userform titled ufDisclaimer, after the user clicks a combo button to import a sheet from an external workbook. The import process uses the File Picker to allow the user to select the file they need imported. The ufDisclaimer has two combo button options to Continue and Cancel. In the Cancel_Click(), I have it first Unloading Me and then Unloading ufRandom. Both userforms successfully unload, but the File Picker still subsequently displays.

Here is what I have in ufDisclaimer:

Private Sub cbCancel_Click()
     Unload Me
     Unload ufRandom
End Sub

So I tried adding an IF to ufRandom to exit if ufDisclaimer's Cancel button was clicked. That didn't stop the File Picker from displaying either. Below is the piece from ufRandom that is supposed to exit if the Cancel button was clicked.

Private Sub Import_Click()

'declarations here

ufDisclaimer.Show

If ufDisclaimer.cbCancel = True Then
     Exit Sub
End If

'rest of code here

End Sub

Any ideas on how to exit the whole operation with the ufDisclaimer Cancel button?

 

[dmt32]

Hi,
place following codes in your ufDisclaimer code page

Function Response() As VbMsgBoxResult
    Me.Show
    Response = Val(Me.Tag)
End Function

Private Sub cmdCancel_Click()
    Me.Tag = vbCancel
    Me.Hide
End Sub

Private Sub cmdContinue_Click()
    Me.Tag = vbYes
    Me.Hide
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    'X pressed
    Cancel = CloseMode = 0
    If Cancel Then Call cmdCancel_Click
End Sub

Change the commandbutton names shown in BOLD as required


To call the code

Private Sub Import_Click()

'declarations here

    If ufDisclaimer.Response = vbCancel Then
   
         Exit Sub
        
    Else
   
        'rest of code here
       
        MsgBox "Show File Picker"
   
   
    End If

End Sub

Dave

 

[dmt32]

Opps sorry, omitted a line code – add line shown in BOLD

Function Response() As VbMsgBoxResult
    Me.Show
    Response = Val(Me.Tag)
    Unload Me
End Function

Dave

 

[breynolds0431]

Opps sorry, omitted a line code – add line shown in BOLD

Function Response() As VbMsgBoxResult
    Me.Show
    Response = Val(Me.Tag)
    Unload Me
End Function

Dave

Thank you, Dave! Works great.

 

[dmt32]

Thank you, Dave! Works great.

most welcome - glad suggestion resolves issue & appreciate the feedback

Dave