Unlock Locked Cell based on another Cell Value

[kiwikiki718]

I have a spread sheet that is Locked/Protected. I want to be able to unlock cell D10 based on the Value of cell C10. so if cell C10 ="Other" I want cell D10 to unlock. else then Cell D10 to remain Lock.

thank You in advance

 

[kiwikiki718]

Thank you @Joe4 I forgot about that...

This will clear D10 :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Or Target.Address <> Range("C10").Address Then Exit Sub
    
    ActiveSheet.Unprotect "YourPassWord"
    
    If Range("C10").Value = "Other" Then
        Range("D10").Locked = False
    Else
        Range("D10").ClearContents
        Range("D10").Locked = True
    End If
    
    ActiveSheet.Protect Password:="YourPassWord"
End Sub

One more thing Louis,

If I had multiple cells in column C that I wanted to apply this code to how would I be able to do so?

example I want to apply this to cells C10:C14 that equals other.

thanks in advance.

 

[louisH]

Then you might change it so Something like this :

Assuming you always want to work with "C" that locks/unlocks "D".
Just change the range in the first line of code to your needs :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Or Intersect(Target, Range("C10:C14")) Is Nothing Then Exit Sub
    
    ActiveSheet.Unprotect "YourPassWord"
    
    If Target.Value = "Other" Then
        Target.Offset(0, 1).Locked = False
    Else
        Target.Offset(0, 1).ClearContents
        Target.Offset(0, 1).Locked = True
    End If
    
    ActiveSheet.Protect Password:="YourPassWord"
End Sub