Unorthodox VBA question

[Janisogor]

Hi, I would like to ask about the programming language of the VBA. I am trying to create a 100x100 matrix of colorful cells. I have found some instructions on how to fill cells with random RGB colors (see below), however I would like to define only 5 colors which I'd like to randomly distribute over the area. I tried modifiyng the code in multiple ways (defining a new set of xRed1, xGreen1, xBlue1; creating multiple modules and triggering them at once etc.) but none of them worked. Even though I know this is probably a fairly easy task I cannot write code and the VBA language is completely new for me. Thank You all for help.

The code:
Sub KEKE()
Dim rng As Range
Dim WorkRng As Range
Dim xRed As Byte
Dim xGreen As Byte
Dim xBule As Byte
On Error Resume Next
xTitleId = "AAA"
Set WorkRng = Application.Selection
Set WorkRng = Application.InputBox("Range", xTitleId, WorkRng.Address, Type:=8)
For Each rng In WorkRng
xRed = Application.WorksheetFunction.RandBetween(0, 255)
xGreen = Application.WorksheetFunction.RandBetween(0, 255)
xBule = Application.WorksheetFunction.RandBetween(0, 255)
rng.Pattern = xlSolid
rng.PatternColorIndex = xlAutomatic
rng.Interior.Color = VBA.RGB(xRed, xGreen, xBule)
Next
End Sub

 

[Fluff]

Hi & welcome to MrExcel.
How about

Sub Janisogor()
   Dim Cl As Range
   Application.ScreenUpdating = False
   For Each Cl In Range("A1:CV100")
      Cl.Interior.ColorIndex = Application.RandBetween(3, 7)
   Next Cl
End Sub

 

[Janisogor]

Thank You for Your reply!

This works fine, however these are Excel's index colors, right? Can I somehow define 5 particular colors and use those?

Thank You again.

 

[Fluff]

Which 5 colours?

 

[Janisogor]

HEX	RGB
#ffffff	(255,255,255)
#f6f6f6	(246,246,246)
#fb742d	(251,116,45)
#47464d	(71,70,77)
#000000	(0,0,0)

 

[Fluff]

Ok, how about

Sub Janisogor()
   Dim Cl As Range
   Dim Ary(1 To 5) As Long
   Ary(1) = 16777215
   Ary(2) = 16185078
   Ary(3) = 2979067
   Ary(4) = 5064263
   Ary(5) = 0
   Application.ScreenUpdating = False
   For Each Cl In Range("A1:CV100")
      Cl.Interior.Color = Ary(Application.RandBetween(1, 5))
   Next Cl
End Sub

 

[Janisogor]

Works a charm. Thank You very much again for Your time.

 

[Fluff]

You're welcome & thanks for the feedback.