User form: Option Button to Fill data range of combobox

[daniels012]

I am attempting to create a user form.
I have created 8 option boxes on my user form.
I have a combobox created on my user form.
Can I add code the when I select option1, it would give me the data from my "Sheet1('sheet1's name is RB) Column C" into my combo box.
Then if I select option2 Sheet2('Sheet2's name is WR) Column C would enter into the combobox.
I have code written that once I choose the item in the combo box, it then places the info into the active cell.

I already thought about making a master list with all the data from all the sheets, but I really would rather them be separate.

Thank you,
Michael

 

[BrianB]

Needs a bit of code for each optionbutton and a shared routine ...

Dim SheetName As String         ' shared variable
'----------------------------------------------------------
Private Sub OptionButton1_Click()
    SheetName = "RB"
    FillCombo
End Sub
'----------------------------------------------------------
Private Sub OptionButton2_Click()
    SheetName = "WR"
    FillCombo
End Sub
'----------------------------------------------------------
Private Sub FillCombo()
    Dim ws As Worksheet
    Dim ToRow As Long
    '------------------------------------------------------
    '- initialise variables
    Set ws = Worksheets(SheetName)
    ToRow = 1
    '------------------------------------------------------
    '- clear combo
    ComboBox1.Clear
    '------------------------------------------------------
    '- write new values
    While ws.Cells(ToRow, "C").Value <> ""
        ComboBox1.AddItem ws.Cells(ToRow, "C").Value
        ToRow = ToRow + 1
    Wend
End Sub
'----------------------------------------------------------

 

[Norie]

Michael

Did you ever try the suggestion i made in your other thread?

ie using a listbox and combobox