UserForm Controls Position

[mikeymay]

I have a UF with many controls and I want all the controls in the UF to have the .Top value to reduce by the same value.

Rather than having to go through each one and change manually, is there a way to perform this via a routine and for the new .Top values to retained on the UF?

 

[Domenic]

First, make sure that you allow access to the Visual Basic Project . . .

Ribbon >> Developer tab >> Code group >> Macro Security >> select/check Trust access to the VBA project model

Then try the following macro . . .

Option Explicit

Sub test()

    On Error Resume Next
    Dim vbp As Object
    Set vbp = ActiveWorkbook.VBProject
    If vbp Is Nothing Then
        MsgBox "Allow access to the Visual Basic Project, and try again!", vbExclamation, "Programmatic Access"
        Exit Sub
    End If
    On Error GoTo 0
  
    Dim uf As String
    uf = "UserForm1" 'change the userform name accordingly

    On Error Resume Next
    Dim vbc As Object
    Set vbc = vbp.VBComponents(uf)
    If vbc Is Nothing Then
        MsgBox "'" & uf & "' is not available!", vbExclamation, "UserForm"
        Exit Sub
    End If
    On Error GoTo 0
  
    Dim ctrl As Object
    For Each ctrl In vbc.designer.Controls
        With ctrl
            .Top = .Top - .Top
        End With
    Next ctrl
  
    MsgBox "Completed!", vbExclamation, "Completed"
  
End Sub

Note that if you actually meant that you want to reduce the top value by the height, replace . . .

.Top = .Top - .Top

with

.Top = .Top - .Height

Hope this helps!