Userform Textbox saving to table

[GedSalter]

Hi all.

I have a userform which imports data from a table. At the moment when a textbox is changed it Saves A:LLthe textbox data back to respective cells. What I need is that the save will only overwrite changed data back into the table and not overwrite data which hasnt changed.

here is my code so far

Private Sub cmdAddData_Click()

Dim i As Long, LastRow As Long, ws As Worksheet

Set ws = Sheets("Sheet2")
LastRow = ws.Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To LastRow


If Me.ComboBox1.Value = ws.Cells(i, "A") Then

ws.Cells(i, "B") = txtFirstname.Value
ws.Cells(i, "C") = TxtSurname.Value
ws.Cells(i, "D") = TxtDOB.Value
ws.Cells(i, "E") = Gender.Value
ws.Cells(i, "F") = Membership.Value

ws.Cells(i, "H") = MemberSince.Value

ws.Cells(i, "G") = FEESnowpaid.Value

ws.Cells(i, "I") = PaidDate.Value


End If

Next i

End Sub

 

[Alex Blakenburg]

The question is somewhat confusing.

and not overwrite data which hasnt changed.

If you are "overwriting" data that hasn't changed, you won't know, so why does it matter ?
Changed in comparison to what ?

 

[GedSalter]

The question is somewhat confusing.

If you are "overwriting" data that hasn't changed, you won't know, so why does it matter ?
Changed in comparison to what ?

because then date stamps change

 

[Alex Blakenburg]

What is doing the date stamping ?
Is it a field for each cell updated or are you relying on Excel tracking / audit features ?

 

[Akuini]

Try :

If ws.Cells(i, "B") <> txtFirstname.Value Then ws.Cells(i, "B") = txtFirstname.Value

do the same thing to other textboxes.

 

[dmt32]

Hi,
untested but see if this update to your code will do what you want

Private Sub cmdAddData_Click()
    Dim m           As Variant, Entry As Variant
    Dim Search      As Variant
    Dim c           As Long
    Dim ws          As Worksheet
    
    Set ws = Sheets("Sheet2")
    Search = Me.ComboBox1.Value
    
    If Len(Search) = 0 Then Exit Sub
    If IsNumeric(Search) Then Search = Val(Search)
    
    m = Application.Match(Search, ws.Columns(1), 0)
    
    If Not IsError(m) Then
        
        For c = 1 To 8
            Entry = Me.Controls(Choose(c, "txtFirstname", "TxtSurname", "TxtDOB", _
                                            "Gender", "Membership", "MemberSince", _
                                            "FEESnowpaid", "PaidDate")).Value
            
            If IsDate(Entry) Then Entry = DateValue(Entry)
            
            With ws.Cells(CLng(m), c + 1)
                If .Value <> Entry Then .Value = Entry
            End With
            
        Next c
    End If
    
End Sub

Dave

 

[GedSalter]

Try :

If ws.Cells(i, "B") <> txtFirstname.Value Then ws.Cells(i, "B") = txtFirstname.Value

do the same thing to other textboxes.

works perfect. Thank you

 

[Akuini]

You're welcome, glad to help & thanks for the feedback.