UserForm VBA // Repeating code in a smart way

[Young Grasshopper]

Hi World!

I have this code in a vba userform. I need every referance cell to increase by one (D1, D2, D3 etc.) for every "IF Then".
My original plan was just to do it manually, as started, but as the code needs to be repeated 100 times, there is probably a faster way to do it..

Private Sub Testbtn_Click()
        
        If Me.ComboBox1.Text = Worksheets("Macrodata").Range("D1").Text Then
            Headline.Value = Worksheets("MacroData").Range("AD2").Value
                Description.Value = Worksheets("MacroData").Range("AE2").Value
                    URL.Value = Worksheets("Responsive Search Ads HUB").Range("D11").Value
         End If
         
         If Me.ComboBox1.Text = Worksheets("Macrodata").Range("D2").Text Then
            Headline.Value = Worksheets("MacroData").Range("AD3").Value
                Description.Value = Worksheets("MacroData").Range("AE3").Value
                    URL.Value = Worksheets("Responsive Search Ads HUB").Range("D12").Value
         End If
         
          If Me.ComboBox1.Text = Worksheets("Macrodata").Range("D3").Text Then
            Headline.Value = Worksheets("MacroData").Range("AD4").Value
                Description.Value = Worksheets("MacroData").Range("AE4").Value
                    URL.Value = Worksheets("Responsive Search Ads HUB").Range("D13").Value
         End If
         
         If Me.ComboBox1.Text = Worksheets("Macrodata").Range("D4").Text Then
            Headline.Value = Worksheets("MacroData").Range("AD5").Value
                Description.Value = Worksheets("MacroData").Range("AE5").Value
                    URL.Value = Worksheets("Responsive Search Ads HUB").Range("D14").Value
         End If
         

End Sub

Any suggestions?
Would appreciate any help

 

[Akuini]

Try:

Private Sub Testbtn_Click()
Dim i As Long

With Worksheets("Macrodata")
        For i = 0 To 3
            If Me.ComboBox1.Text = .Range("D1").Offset(i).Text Then
                Headline.Value = .Range("AD2").Offset(i).Value
                    Description.Value = .Range("AE2").Offset(i).Value
                        Url.Value = Worksheets("Responsive Search Ads HUB").Range("D11").Offset(i).Value
                Exit For  'once the criteria are met, no need to check the rest, so exit the loop
            End If
        Next
End With
         
End Sub

 

[Young Grasshopper]

You're a lifesaver, Akuini.. Works perfect and saves me hours of work!
If i would like the code to go over 100 rows i can just tweak it to "For i = 0 To 99", right?

 

[Akuini]

If i would like the code to go over 100 rows i can just tweak it to "For i = 0 To 99", right?

Correct

 

[Young Grasshopper]

beautiful!
Thanks again, and enjoy the rest of your day

 

[Akuini]

You're welcome, glad to help & thanks for the feedback.