Using a macro to highlight a case sensitive text

[hnt007]

Hello and many thanks for helping me out!

I'd need some help to update the following code to make it case sensitive, please. I just want to highlight "Sec" not "sec"

Sub Sec()
Dim rng As Range, c As Range, i As Long, mystring As String, tmp As String
Application.ScreenUpdating = False
Set rng = Range("D8:D1000")
mystring = "Sec"

For Each c In rng
For i = 1 To Len(c)
tmp = Mid(c, i, 1)
If InStr(1, mystring, tmp, 0) Then c.Characters(i, 1).Font.Color = vbRed
Next i
Next c
Application.ScreenUpdating = True
End Sub

 

[Rick Rothstein]

Try it like this...

Sub Sec()
  Dim Pos As Long, rng As Range, c As Range, mystring As String
  Application.ScreenUpdating = False
  Set rng = Range("D8:D1000")
  mystring = "Sec"
  
  For Each c In rng
    Pos = InStr(c.Value, mystring)
    Do While Pos
      c.Characters(Pos, Len(mystring)).Font.Color = vbRed
      Pos = InStr(Pos + 1, c.Value, mystring)
    Loop
  Next
  Application.ScreenUpdating = True
End Sub

 

[bebo021999]

Option Explicit
Sub Sec()
Dim lr&, i&, cell As Range, mystring As String
mystring = "Sec"
lr = Cells(Rows.Count, "D").End(xlUp).Row
    For Each cell In Range("D1:D" & lr)
            For i = 1 To Len(cell)
                With cell.Characters(i, 1)
                    If mystring Like "*" & .Text & "*" Then
                        .Font.Color = vbRed
                    End If
                End With
            Next
    Next
End Sub

 

[kevin9999]

Option Explicit
Sub Highlight_Sec()
    Dim rng As Range, c As Range, myString As String, i As Long
    Set rng = Range("D8:D1000")
    myString = "Sec"
    
        For Each c In rng
            For i = 1 To Len(c) - Len(myString) + 1
                If Mid(c, i, Len(myString)) = myString Then
                    c.Characters(i, Len(myString)).Font.Color = vbRed
                End If
            Next i
        Next c
End Sub

 

[hnt007]

Try it like this...

Sub Sec()
  Dim Pos As Long, rng As Range, c As Range, mystring As String
  Application.ScreenUpdating = False
  Set rng = Range("D8:D1000")
  mystring = "Sec"
 
  For Each c In rng
    Pos = InStr(c.Value, mystring)
    Do While Pos
      c.Characters(Pos, Len(mystring)).Font.Color = vbRed
      Pos = InStr(Pos + 1, c.Value, mystring)
    Loop
  Next
  Application.ScreenUpdating = True
End Sub

This is working great!! Thanks!