Using "IF" formula

[Number Cruncher 1969]

Morning,

A little difficult to explain what I'm trying to achieve but is it possible to use two if statements in one formula eg

Date	Dept	Company	Net	VATable (Y/N)	20% A	13.5% B
19/03/2021	Sales	A	1000	y

if Company ="A" and VATable = "Y" then in 20% A = £200 otherwise £0.00

I appreciate its not the best worded question but any help greatly appreciated.

Thanks
C.

 

[etaf]

did you want something like
Assuming Column C = Company
IN F2
=IF(AND(C2="A", E2="Y"), 20%, 0)
IN G2
=IF(AND(C2="B", E2="Y"), 13.5%, 0)

If you had the % in a cell in the header on there own, then you could use that cell for the %

I assume its the D column you want the % of
IN F2
=IF(AND(C2="A", E2="Y"), D2*0.2, 0)
IN G2
=IF(AND(C2="B", E2="Y"), D2*0.135, 0)

 

[Number Cruncher 1969]

did you want something like
Assuming Column C = Company
IN F2
=IF(AND(C2="A", E2="Y"), 20%, 0)
IN G2
=IF(AND(C2="B", E2="Y"), 13.5%, 0)

If you had the % in a cell in the header on there own, then you could use that cell for the %

I assume its the D column you want the % of
IN F2
=IF(AND(C2="A", E2="Y"), D2*0.2, 0)
IN G2
=IF(AND(C2="B", E2="Y"), D2*0.135, 0)

Thank you for the quick reply, I will give the above a go and let you know!

 

[etaf]

i have changed the layout slightly - so the % is in a separate cell and then you can use that % and if will change all the values

Book3
	A	B	C	D	E	F	G
1	Date	Dept	Company	Net	VATable	A	B
2					(Y/N)	20%	13.50%
3	3/19/21	Sales	A	1000	y	200	0
4	3/20/21	Sales	A	10000	y	2000	0
5	3/21/21	Sales	A	100	n	0	0
6	3/22/21	Sales	b	100	y	0	13.5
7	3/23/21	Sales	b	10	y	0	1.35
Sheet1

Cell Formulas
Range	Formula
F3:F7	F3	=IF(AND($C3="A", $E3="Y"), $D3*F$2, 0)
G3:G7	G3	=IF(AND($C3="B", $E3="Y"), $D3*G$2, 0)

 

[jtakw]

Hi,

Since etaf already suggested and created a different lay out, with etaf's lay out, we can also use F1:H1 for company reference:

Book3.xlsx
	A	B	C	D	E	F	G	H
1	Date	Dept	Company	Net	VATable	A	B	C
2					(Y/N)	20%	13.50%	10%
3	3/19/2021	Sales	A	1000	y	200	0	0
4	3/20/2021	Sales	A	10000	y	2000	0	0
5	3/21/2021	Sales	A	100	n	0	0	0
6	3/22/2021	Sales	b	100	y	0	13.5	0
7	3/23/2021	Sales	b	10	y	0	1.35	0
8	3/19/2021	Sales	C	5000	Y	0	0	500
Sheet849

Cell Formulas
Range	Formula
F3:H8	F3	=IF(AND($C3=F$1,$E3="Y"),$D3*F$2,0)