Utility to covert a mass of .doc files to .txt

[PatPat]

hello

I am looking for a way to convert a mass of .doc files to .txt files.

Can anyone make some suggestions?

Thanks

 

[Macropod]

Hi Pat,

You could use a macro to loop through all the .doc files in a folder, open them, then save as a text file. For example, with the following code, you simply select the folder to process and Word will make .txt copies of all the .doc files in it:

Sub ConvertDocuments()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
  wdDoc.SaveAs FileName:=wdDoc.Name, FileFormat:=wdFormatText
  wdDoc.Close SaveChanges:=True
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

 

[PatPat]

Thanks very much for this I will try it and let you know.

 

[PatPat]

Hi there

I am getting a "Compile Error: User- defined type not defined" on Dim wdDoc As Document.

Doed this mean I am on a different version or have you created Docment as a type?

Thanks

 

[Macropod]

That error suggests you're not running the macro from Word.

 

[PatPat]

Thanks. I was running it in Word but when I reinstalled a service pack it seemed to work fine.