Validate

[kenpcli]

Why wont this script color the column M if it meets both criteria:

Sub Validate()


Dim found As Boolean
found = False
For Each cell In Range("F2:M1000").Cells
If cell.Value = "FT Hourly" And "<40" Then
found = True
End If
Next
If found = True Then
cell.Select.Interior.ColorIndex = 9

End If
End Sub

Thanks

 

[JoeMo]

This line:

If cell.Value = "FT Hourly" And "<40" Then

is likely the problem. What is the bit in red intended to do?

 

[reberryjr]

Can you upload a couple of rows that meet your condition? I'd like to see how the data is structured.

 

[Rick Rothstein]

Why wont this script color the column M if it meets both criteria:

Sub Validate()


Dim found As Boolean
found = False
For Each cell In Range("F2:M1000").Cells
If cell.Value = "FT Hourly" And "<40" Then
found = True
End If
Next
If found = True Then
cell.Select.Interior.ColorIndex = 9

End If
End Sub

What exactly is the red highlighted line of code above trying to test for? Either a cell has text in it or it has a number in it, both cannot be true (your use of the And operator makes it seem like you think it can).

Also, what is the overall purpose of this code? There are other structural problems with your code besides the above, but I won't know how to fix them until I know what you want this code to actually do.

 

[kenpcli]

I am trying to get it to look at column F (Pay Class)and find any FT Hourly it is FT Hourly then look at Column M (Total) in the same row and see if it is less 40, if so it color fills it.

Home Company	Full Name	ID Number	Home Site	Home Department	Pay Class Name	Regular	Overtime	PTO	FTO	REGPOR	PORSL	Total
PCLI-Corp			1	30	FT Hourly	40.00						40.00
PCLI-Corp			1	30	FT Hourly	39.95						39.95
PCLI-Corp			1	30	FT Hourly	40.00						40.00
PCLI-Corp			1	30	FT Hourly	39.75						39.75
PCLI-Corp			1	30	FT Hourly	26.80		13.20				40.00
PCLI-Corp			1	30	FT Hourly	40.00						40.00
PCLI-Corp			1	30	FT Hourly	31.25		8.75				40.00
PCLI-Corp			1	30	FT Hourly	40.00						40.00
PCLI-Corp			1	30	Hourly PT							0.00

<tbody>
</tbody><colgroup><col><col><col><col><col><col><col><col><col><col><col><col><col></colgroup>

 

[JoeMo]

Maybe:

Sub Validate()
Dim cell As Range
Application.ScreenUpdating = False
For Each cell In Range("F2:F1000")
If cell.Value = "FT Hourly" And cell.Offset(0, 7).Value < 40 Then cell.Offset(0, _
    7).Interior.ColorIndex = 9
Next cell
Application.ScreenUpdating = True
End Sub

 

[Rick Rothstein]

Here is another macro for you to consider...

[table="width: 500"]
[tr]
	[td]Sub Validate()
  Dim R As Long
  Application.ScreenUpdating = False
  For R = 2 To Cells(Rows.Count, "F").End(xlUp).Row
    If Cells(R, "F").Value = "FT Hourly" And Cells(R, "M").Value < 40 Then Cells(R, "M").Interior.ColorIndex = 9
  Next
  Application.ScreenUpdating = True
End Sub[/td]
[/tr]
[/table]

 

[kenpcli]

Thank you, worked like a charm.