VarType returning "wrong" result for Variant data !

[Jaafar Tribak]

Hi all,

Does anybody know why VarType returns vbString when it should return vbObject ?

Sub Test()

    Dim v As Variant
  
    Set v = Application
    MsgBox VarType(v)  '<== returns 8(vbString) instead of 9(vbObject) !!

End Sub

when assigning other objects to the variant variable other than "Application" , it seems to work as expected.

I have also tried Set v = Excel.Application and Set v = Application.Application but still no joy.

TypeName does work fine and returns Application as expected.

Am I missing something ?

 

[Rick Rothstein]

If you type this into the Immediate Window...

? Application

It returns this...

Microsoft Excel

which looks like a text string to me (it is also what is returned if you append .Name onto the end of Application). I'm guessing that Application defaults to its Name property when not being used in a situation that needs it to be an object.

EDIT NOTE: I just saw this note in the help files for Application... "Use the Application property to return the Application object".

 

[Jaafar Tribak]

If you type this into the Immediate Window...

? Application

It returns this...

Microsoft Excel

which looks like a text string to me (it is also what is returned if you append .Name onto the end of Application). I'm guessing that Application defaults to its Name property when not being used in a situation that needs it to be an object.

Thanks Rick,

When using Set Keyword it should resolve to the application object ... Also, that's why I tested Application.Application to ensure it doesn't default to the Name Property but still won't work.

 

[Jaafar Tribak]

In fact it doesn't work , even when assigning the Application object to an Object or Application Variable !

Sub Test()

    Dim v As Application
    
    Set v = Application
    MsgBox VarType(v)  '<== returns 8(vbString) instead of 9(vbObject) !!

End Sub

 

[Jaafar Tribak]

The native VarType is problematic. Here is a replacement that works because it looks at the actual data type which is stored in the first 2 bytes of the variant.

Option Explicit

#If VBA7 Then
    Private Declare PtrSafe Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As LongPtr)
#Else
    Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
#End If

Private Function MyVarType(ByRef v As Variant) As VbVarType
    Call CopyMemory(MyVarType, v, 2)
End Function

Sub Test()
    Dim v As Variant
    Set v = Application
    Debug.Print VarType(v), MyVarType(v)
End Sub

Excerpt from Documentation reagarding the Variant Data Type:
A variable of variant type, for brevity called a "variant", as defined in Visual Basic, needs 16 bytes storage and its layout is as follows:
Offset || Size || Description
0 || 2 || The value returned by VarType; specifies what kind of data the variant contains.
2 || 6 || Reserved bytes; should be set to zero.
8 || up to 8 The data the variant contains.

 

[ZVI]

Hi Jaafar,

Hm, hever tried to test this...
At least Debug.Print IsObject(Application) works

 

[Jaafar Tribak]

Hi Jaafar,

Hm, hever tried to test this...
At least Debug.Print IsObject(Application) works

Thanks ZVI,

IsObject works but I just wanted to know why VarType doesn't return vbObject in this case as one would expect.

 

[ZVI]

It is because the (default) hidden property _Default of class Application is declared As String.
VBE - Object Browser - right click, tick Show Hiddden Members - Application.[_Default]
But the reason of such a declaration is unknown to me.

 

[Jaafar Tribak]

It is because the (default) hidden property _Default of class Application is declared As String.
VBE - Object Browser - right click, tick Show Hiddden Members - Application.[_Default]
But the reason of such a declaration is unknown to me.

Thanks.

Yes, I know the Default Property is the Name Property which a string hence the returned vbString from the VarType function.
This makes the native VarType function very misleading.
As I mentioned in previous posts, one would expect that the Set keyword would coerce the variable into an object but that doesn't seem to reflect on the VarType result .. This is what I find difficult to accept.