vb question

[macangc]

Hi

I would like to know how to do the following
I have a spreadsheet where the user can click on a button and it will find todays date on another sheet. using the code below

Sub MyFind()

' Capture value to find from sheet 1
Dim myFindDate As Date
myFindDate = Sheets("Front").Range("iv1")

' Find value on sheet 2
Sheets("Jan").Activate
On Error GoTo err_chk
Cells.Find(What:=myFindDate, After:=ActiveCell, LookIn:=xlFormulas, LookAt _
:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
False).Offset(1, 1).Activate
On Error GoTo 0

But what I would like to know is how i can have each month e.g. Jan, Feb etc to be in different tabs but use the same button on the first page to find "todays" date

For example if todays date was 18/03/2007 i would click on the button and it would search through each months sheet untill it found the correct date.

hope it makes sense.. thanks

 

[lozzablake]

This should do what you want. I have removed the error check and instead put in a boolean which flags whether or not the date is found. You can always put something else within the final IF clause

Sub MyFind()
    
    Dim blnFound As Boolean    'flag to see if date is found
    Dim mySheet As Worksheet
    Dim myFindDate As Date
    Dim rngFound As Range      'holds found range
    
    blnFound = False
    
    'Capture value to find from sheet 1
    myFindDate = Sheets("Front").Range("iv1")
    
    
    'loop through all sheets until date is found
    For Each mySheet In ThisWorkbook.Sheets
        
        Set rngFound = mySheet.Cells.Find(What:=myFindDate)
        If Not rngFound Is Nothing And mySheet.Name <> "Front" Then
            blnFound = True
            Exit For
        End If
    Next mySheet
    
    If blnFound Then
        mySheet.Activate
        rngFound.Offset(1, 1).Select
    Else
        MsgBox Format(myFindDate, "dd-mmm-yy") & " not found"
    End If
End Sub

 

[macangc]

Thankyou very much, works like a charm