VBA Code help: Want to save unhide worksheets as pdf

[Jasperlee93]

Sub ExportPDF()

Dim FDialog As FileDialog
Dim FPath As String
Dim Sht As Worksheet

Application.ScreenUpdating = False
Application.DisplayAlerts = False

Set FDialog = Application.FileDialog(msoFileDialogFolderPicker)
FDialog.InitialFileName = ThisWorkbook.Path

If FDialog.Show = -1 Then
FPath = FDialog.SelectedItems(1)
End If

If FPath <> "" Then

For Each Sht In ThisWorkbook.Sheets
Sht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FPath _
& Application.PathSeparator & Sht.Name & ".pdf"
Next Sht

End If

Application.ScreenUpdating = True
Application.DisplayAlerts = True

End Sub


above vba code is what I am currently using.

 

[Jimmypop]

Hi there

Try the below... From your question I am guessing you only want to export sheets that are not hidden...

Sub ExportPDF()
    Dim FDialog     As FileDialog
    Dim FPath       As String
    Dim Sht         As Worksheet
    Application.ScreenUpdating = FALSE
    Application.DisplayAlerts = FALSE
    Set FDialog = Application.FileDialog(msoFileDialogFolderPicker)
    FDialog.InitialFileName = ThisWorkbook.Path
    If FDialog.Show = -1 Then
        FPath = FDialog.SelectedItems(1)
    End If
    If FPath <> "" Then
        For Each Sht In ThisWorkbook.Sheets
            If Sht.Visible = xlSheetVisible Then
                Sht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FPath _
                                      & Application.PathSeparator & Sht.Name & ".pdf"
            End If
        Next Sht
    End If
    Application.ScreenUpdating = TRUE
    Application.DisplayAlerts = TRUE
End Sub

 

[Jasperlee93]

Thank you for your help.
It works!

 

[Jimmypop]

Glad we could assist and thanks for the feedback