VBA Code to Alphabetize Between Two Tabs

[OilEconomist]

Thanks in advance as I'll try to post feedback.

How do I alphabetize the sheets that are between the "Start" and "End" sheets. I have sheets before Start and End, but I want them to stay where they are. Now what's happening is all the sheets are being alphabetized.

Sub Alp()

 '_______________________________________________________________________________________________
        'Turn on alerts, screen updates, and calculate
            'Turn On Display Alerts
                Application.DisplayAlerts = True

            'Turn on Screen Update
                Application.ScreenUpdating = True

            'Turn off Automatic Calculations
                Calculate


 Dim Sht_Start As Long
            Dim Sht_End As Long
            Dim i As Long
            Dim j As Long
            

'Alphabetize
            Sht_Start = Worksheets("Start").Index - 1
            Sht_End = Worksheets("End").Index - 1
            
            
            For i = Sht_Start To Sht_End
            
                    For j = Sht_Start To Sht_End - 1
                    
                        If UCase$(Application.Sheets(j).Name) > _
                            UCase$(Application.Sheets(j + 1).Name) Then
                            
                                Sheets(j).Move after:=Sheets(j + 1)
                                
                        End If
                        
                    Next
                    
                Next

 '_______________________________________________________________________________________________
        'Turn on alerts, screen updates, and calculate
            'Turn On Display Alerts
                Application.DisplayAlerts = True

            'Turn on Screen Update
                Application.ScreenUpdating = True

            'Turn off Automatic Calculations
                Calculate
                
                

End Sub

 

[JoeMo]

Sub AlphabetizeSheets()
Dim Sht_Start As Long, Sht_End As Long, i As Long, j As Long
Sht_Start = Worksheets("Start").Index
Sht_End = Worksheets("End").Index
Application.ScreenUpdating = False
For i = Sht_Start + 1 To Sht_End - 1
    For j = Sht_Start + 1 To Sht_End - 2
        If UCase$(Application.Sheets(j).Name) > _
            UCase$(Application.Sheets(j + 1).Name) Then
                Sheets(j).Move after:=Sheets(j + 1)
        End If
    Next j
Next i
Application.ScreenUpdating = True
End Sub

 

[OilEconomist]

@JoeMo that worked like a charm. Thanks so much and thanks for using as much of my original code as possible.

 

[JoeMo]

@JoeMo that worked like a charm. Thanks so much and thanks for using as much of my original code as possible.

You are welcome - thanks for the rpely.