VBA Code to clear cell borders

[learningexcel123]

I'm sure there's a quicker way and also not sure what is wrong with my code but I need the code to loop through a workbook, making changes only to the worksheets listed in the array. The change needed is to clear all borders in cells F62:F165 with the exception of the right border. My code clears all borders first and then adds right border back in. The problem is that the code only changes the cells in the active sheet I am on and not the ones specified in the array. Secondly, I'm hoping there's a shorter code out there:

Sub Clear_Borders()
Dim ws As Worksheet
For Each ws In Sheets(Array("Sheet1", "Sheet2"))
Range("F62:F165").Select
Selection.Borders(xlDiagonalDown).LineStyle = xlNone
Selection.Borders(xlDiagonalUp).LineStyle = xlNone
Selection.Borders(xlEdgeLeft).LineStyle = xlNone
Selection.Borders(xlEdgeTop).LineStyle = xlNone
Selection.Borders(xlEdgeBottom).LineStyle = xlNone
Selection.Borders(xlEdgeRight).LineStyle = xlNone
Selection.Borders(xlInsideVertical).LineStyle = xlNone
Selection.Borders(xlInsideHorizontal).LineStyle = xlNone
Selection.Borders(xlDiagonalDown).LineStyle = xlNone
Selection.Borders(xlDiagonalUp).LineStyle = xlNone
Selection.Borders(xlEdgeLeft).LineStyle = xlNone
Selection.Borders(xlEdgeTop).LineStyle = xlNone
Selection.Borders(xlEdgeBottom).LineStyle = xlNone
With Selection.Borders(xlEdgeRight)
.LineStyle = xlContinuous
.ColorIndex = xlAutomatic
.TintAndShade = 0
.Weight = xlThin
End With
Selection.Borders(xlInsideVertical).LineStyle = xlNone
Selection.Borders(xlInsideHorizontal).LineStyle = xlNone
Next ws
End Sub

Thanks for your help!

 

[jbeaucaire]

You need to address your commands to the ws objects directly so the commands occur ON those sheets. Also, you can always abbreviate code relating to borders and remove the "selecting" from your recorded macros:

 Option Explicit

Sub Clear_Borders()
Dim ws As Worksheet

    For Each ws In Sheets(Array("Sheet1", "Sheet2"))
        With ws.Range("F62:F165")
            .Borders.LineStyle = xlNone
            .Borders(xlEdgeRight).Weight = xlThin
        End With
    Next ws

End Sub

The line of code in red doesn't single out any one specific border, so it applies that command to ALL of them.

 

[learningexcel123]

Merci Jerry, it worked beautifully! Thanks.