VBA Code to hide rows on selected sheets based on cell value

[mkpippin]

Hi All,

I'm looking to add a macro that will cycle through a few specific worksheets (Sheet1, Sheet2, Sheet3) and hide rows if the value in column A of that row equals "Hide". This should seemingly be simple, but I can't quite get it to work.

Any insight would be greatly appreciated

Thanks!!

 

[Joe4]

Why not just use Filters to do it?
If you want VBA, you can use VBA to set up the Filters. You can turn on the Macro Recorder and record yourself doing it to get much of the code you need to do this.

 

[mkpippin]

Filters won't work for me in this scenario because I have many end users who will be filtering and clearing filters on this sheet. When they clear the filters, I want these rows to still be hidden

 

[Trebor76]

Hi mkpippin,

Try this:

Option Explicit
Sub Macro1()

    Dim varMySheet As Variant
    Dim wsMySheet  As Worksheet
    Dim lngLastRow As Long
    Dim lngMyRow   As Long
    Dim xlnCalcMethod As XlCalculation
    
    With Application
        .ScreenUpdating = False
        xlnCalcMethod = .Calculation
        .Calculation = xlCalculationManual
    End With
    
    For Each varMySheet In Array("Sheet1", "Sheet2", "Sheet3")
        Set wsMySheet = Sheets(CStr(varMySheet))
        lngLastRow = wsMySheet.Cells(Rows.Count, "A").End(xlUp).Row
        For lngMyRow = lngLastRow To 1 Step -1
            If StrConv(wsMySheet.Range("A" & lngMyRow), vbProperCase) = "Hide" Then
                wsMySheet.Rows(lngMyRow).Hidden = True
            Else
                wsMySheet.Rows(lngMyRow).Hidden = False
            End If
        Next lngMyRow
        Set wsMySheet = Nothing
    Next varMySheet
    
    With Application
        .Calculation = xlnCalcMethod
        .ScreenUpdating = True
    End With

End Sub

Regards,

Robert