VBA Conditional Formatting Colors

[Littlemalky]

I'm super confused. So i have my code set up that I pretty much just adjusted from the recorder macro with the exact color reference that the recorder created, however, when I run my macro with that same color number it gave me, it breaks and doesn't recognize it. Does anyone know how to make my font red? This is what I have:

LastRow = ActiveSheet.UsedRange.Row - 1 + ActiveSheet.UsedRange.Rows.Count
    Range("E2:E" & LastRow).FormatConditions.Add Type:=xlTextString, String:="D-", TextOperator:=xlBeginsWith
    Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
    With Selection.FormatConditions(1).Font
        .Color = 3
        .TintAndShade = 0
    End With
    Selection.FormatConditions(1).StopIfTrue = False

 

[Littlemalky]

Oops, I apologize the number that the recorder gave me was "-16776961", not 3, 3 is the alternative I tried, but didn't work.

 

[Marcelo Branco]

Hi,

Try this

Sub Test1()
    Dim lastRow As Long
    
    With ActiveSheet
        lastRow = .Cells(.Rows.Count, "E").End(xlUp).Row
        
        With .Range("E2:E" & lastRow)
            .FormatConditions.Add Type:=xlTextString, String:="D-", TextOperator:=xlBeginsWith
            .FormatConditions(.FormatConditions.Count).SetFirstPriority
            With .FormatConditions(1).Font
                .ColorIndex = 3
                .TintAndShade = 0
            End With
            .FormatConditions(1).StopIfTrue = False
        End With
        
    End With
   
End Sub

HTH

M.

 

[Littlemalky]

That worked perfectly, thank you so much.

 

[Marcelo Branco]

That worked perfectly, thank you so much.

Glad to help

Tks for the feedback

M.