vba copy and paste from one worksheet to another using different paste special method

[mychi11]

here is my code . I was wondering if i can PasteSpecial xlPasteValues, xlPasteSpecialOperationAdd for column C and H only ? , while others just PasteSpecial xlPasteValues

Sub Copy_Paste_Below_Last_Cell()
'Find the last used row in both sheets and copy and paste data below existing data.

Dim wsCopy As Worksheet
Dim wsDest As Worksheet
Dim lCopyLastRow As Long
Dim lDestLastRow As Long

'Set variables for copy and destination sheets
Set wsCopy = Workbooks("inv.xlsx").Worksheets(1)
Set wsDest = Workbooks("labinventory.xlsm").Worksheets("Master")

'1. Find last used row in the copy range based on data in column A
lCopyLastRow = wsCopy.Cells(wsCopy.Rows.Count, "A").End(xlUp).Row

'2. Find first blank row in the destination range based on data in column A
'Offset property moves down 1 row
lDestLastRow = wsDest.Cells(wsDest.Rows.Count, "A").End(xlUp).Offset(1).Row

'3. Copy & Paste Data
wsCopy.Range("A2:L" & lCopyLastRow).Copy
wsDest.Range("A" & lDestLastRow).PasteSpecial xlPasteValues

End Sub

 

[DanteAmor]

Maybe in parts:

  '3. Copy & Paste Data
  'wsCopy.Range("A2:L" & lCopyLastRow).Copy
  wsCopy.Range("A2:B" & lCopyLastRow).Copy
  wsDest.Range("A" & lDestLastRow).PasteSpecial xlPasteValues
  
  wsCopy.Range("C2:C" & lCopyLastRow).Copy
  wsDest.Range("C" & lDestLastRow).PasteSpecial xlPasteValues, xlPasteSpecialOperationAdd
  
  wsCopy.Range("D2:G" & lCopyLastRow).Copy
  wsDest.Range("D" & lDestLastRow).PasteSpecial xlPasteValues
  
  wsCopy.Range("H2:H" & lCopyLastRow).Copy
  wsDest.Range("H" & lDestLastRow).PasteSpecial xlPasteValues, xlPasteSpecialOperationAdd
  
  wsCopy.Range("I2:L" & lCopyLastRow).Copy
  wsDest.Range("I" & lDestLastRow).PasteSpecial xlPasteValues

 

[mychi11]

The code works perfectly. Thank you so much, DanteAmor!

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.