VBA Copy column paste to sheet based on Month header

[Glytch]

Hello all,
I need some help, i went through several threads and didnt find a solution.

I have a file as example composed of 3 sheets
Sheet 1 "Month selection" - were user will pick the month he is working on
Sheet 2 "a) PL+BS+RE" - P&L statement were numbers will be finalized on collumn O
Sheet 3 - "A) P&L+BS" - Archive sheet were i want to paste collumn O to the correct month collumn

O2 cell will have the month name.
But i cant get the code to copy over the collumn to the correct month.

Any help would be much appreciated.

File example here: File Example Gofile

 

[DanteAmor]

Try this

Sub CopyMonth()
  Dim f As Range, sMon As String, lr As Long
  Dim sh1 As Worksheet, sh2 As Worksheet, sh3 As Worksheet
  
  Set sh1 = Sheets("Month selection")
  Set sh2 = Sheets("a) PL+BS+RE")
  Set sh3 = Sheets("A) P&L+BS")
  
  sMon = sh1.Range("B1").Value
  If sMon = "" Then
    MsgBox "Select month"
    Exit Sub
  End If
  
  Set f = sh3.Rows(3).Find(sMon, , xlValues, xlWhole)
  If Not f Is Nothing Then
    lr = sh2.Range("C" & Rows.Count).End(3).Row
    sh3.Range(sh3.Cells(5, f.Column), sh3.Cells(lr, f.Column)).Value = sh2.Range("O5:O" & lr).Value
  Else
    MsgBox "Month does not exists"
  End If
End Sub

 

[Glytch]

Try this

Sub CopyMonth()
  Dim f As Range, sMon As String, lr As Long
  Dim sh1 As Worksheet, sh2 As Worksheet, sh3 As Worksheet
 
  Set sh1 = Sheets("Month selection")
  Set sh2 = Sheets("a) PL+BS+RE")
  Set sh3 = Sheets("A) P&L+BS")
 
  sMon = sh1.Range("B1").Value
  If sMon = "" Then
    MsgBox "Select month"
    Exit Sub
  End If
 
  Set f = sh3.Rows(3).Find(sMon, , xlValues, xlWhole)
  If Not f Is Nothing Then
    lr = sh2.Range("C" & Rows.Count).End(3).Row
    sh3.Range(sh3.Cells(5, f.Column), sh3.Cells(lr, f.Column)).Value = sh2.Range("O5:O" & lr).Value
  Else
    MsgBox "Month does not exists"
  End If
End Sub

This is perfect. Its working exactly as needed.
Thank you for the time and support on this.

 

[DanteAmor]

I'm glad to help you. Thanks for the feedback.