vba copy from one table to another

[ldarley]

Hi,

I'm getting a getting a runtime error 1004 on this line tbl2.ListRows(x).Range.PasteSpecial xlPasteAll (full code below). I've tried a few variations on this and can't seem to get the copied table row to paste into my second table. The range size is exactly the same and they are one two different worksheets. Can anyone point out where I've gone wrong?

Many Thanks

Dim ProjectID As Long
Dim ws1 As Worksheet
Dim ws2 As Worksheet
Dim tbl1 As ListObject
Dim tbl2 As ListObject
Dim CopyRow As Range
Dim i As Long
Dim x As Long  

        'set up variables
        Set ws1 = Projects
        Set tbl1 = ws1.ListObjects("ProjectTbl")
        Set ws2 = Closed
        Set tbl2 = ws2.ListObjects("ClosedTbl")
        ProjectID = UserForm2.ProjectIDCmb.Value

        i = Application.WorksheetFunction.Match(ProjectID, tbl1.ListColumns(1).DataBodyRange, 0)
        Set CopyRow = tbl1.ListRows(i).Range
        CopyRow.Copy
  
        Set newrow = tbl2.ListRows.Add
        x = tbl2.ListRows.Count
        tbl2.ListRows(x).Range.PasteSpecial xlPasteAll

 

[AlphaFrog]

When you do a .ListRows.Add to a table, it clears the copied range from the clipboard. Then there is nothing to PasteSpecial any more. Move your .Copy command to after the .ListRows.Add

        i = Application.WorksheetFunction.Match(ProjectID, tbl1.ListColumns(1).DataBodyRange, 0)
        'Set CopyRow = tbl1.ListRows(i).Range
        'CopyRow.Copy
  
        Set newrow = tbl2.ListRows.Add
        'x = tbl2.ListRows.Count
        tbl1.ListRows(i).Range.Copy
        newrow.Range.PasteSpecial xlPasteAll

Alternatively, you could use the Range.Value = Range.Value method or the Range.Copy Destination:=Range method

 

[ldarley]

Awesome thanks Alpha frog great learning point for me about the clipboard!

 

[AlphaFrog]

As a general rule when using PasteSpecial, try to place the Copy command immediately before the PasteSpecial command.

You're welcome and thanks for the feedback.