VBA Copying and pasting certain columns to another worksheet

[VBAExpertWannabe]

I'm trying to do a macro where I will copy data for a column that will be dynamic in Sheet 2, to the current worksheet, Column D. The dynamic column are months, January, February, March...and I want a macro so that if I input the month of "12", that, it will pick that column and then copy the entire column over to the first tab. So I guess I need a mechanism for tying the month to a column name/number?

Right now, my code is static but would like to make it dynamic.

Sub CopyPaste()

Windows("book1.xlsm").Activate
Worksheets("Actual Budget").Activate
Range("M4").Select
Range(Selection, Selection.End(xlDown)).Select
Selection.Copy
Worksheets("DECEMBER Summary").Activate
Range("D3").Select
ActiveSheet.Paste

End Sub

Please see screenshots below.

 

[DanteAmor]

Hi and welcome to the board!

Try this code, Enter the month in cell H1 of the "DECEMBER Summary" sheet

Sub Copying_pasting_certain_columns()
  Dim sh1 As Worksheet, sh2 As Worksheet, m As Variant, lr As Long
  
  Set sh1 = Sheets("DECEMBER Summary")
  Set sh2 = Sheets("Actual Budget")
  
  m = sh1.Range("H1").Value
  If m = "" Or m < 1 Or m > 12 Or Not IsNumeric(m) Then
    MsgBox "Enter number of month in H1"
    Exit Sub
  End If
  lr = sh2.Cells(Rows.Count, m + 1).End(xlUp).Row
  sh2.Range(sh2.Cells(4, m + 1), sh2.Cells(lr, m + 1)).Copy
  sh1.Range("D3").PasteSpecial xlPasteValues
  Application.CutCopyMode = False
End Sub

 

[VBAExpertWannabe]

Thank you sooo much! It worked PERFECTLY!

I'm relatively new to VBA but could you please explain the following..

lr = sh2.Cells(Rows.Count, m + 1).End(xlUp).Row
sh2.Range(sh2.Cells(4, m + 1), sh2.Cells(lr, m + 1)).Copy

 

[DanteAmor]

Thank you sooo much! It worked PERFECTLY!

I'm relatively new to VBA but could you please explain the following..

Get the last row with data from the captured month column
lr = sh2.Cells(Rows.Count, m + 1).End(xlUp).Row
m = month number + 1, if you put 1 then the column is 2, if you put 12 then the column is 13 (column M)

copy from cell (4, column m + 1) to column (last row with data, column m + 1)
sh2.Range(sh2.Cells(4, m + 1), sh2.Cells(lr, m + 1)).Copy
ex:
sh2.Range(sh2.Cells(4, 13), sh2.Cells(lr, 13)).Copy

I'm glad to help you. Thanks for the feedback.