VBA display current hour

[hailstorm]

Hello there,

I have this simple code running which shows me the date and hour when i first open my userform, the problem is that i want the hour to keep updating as long as the user remains with the form open. How can i do that?

Private Sub UserForm_Initialize()

data = Date
hora = Time

data.Enabled = True
hora.Enabled = True

End Sub

 

[Legacy 456155]

One way is to use Application.OnTime. Another is to use an API timer, which is my preference, but some people think it's too risky.
Here is an example using OnTime.

In a static module:

Option Explicit

Private CallBackRef As Object
Private NextTick As Date
Private NumSeconds As Long

Sub StartTimer(CallBackThis As Object, NumberOfSeconds As Long)
    Set CallBackRef = CallBackThis 
    NumSeconds = NumberOfSeconds
    TickTock
End Sub

Sub TickTock()
    NextTick = Now + TimeSerial(0, 0, NumSeconds)
    Application.OnTime NextTick, "TickTock"
    CallBackRef.Timer
End Sub

Sub StopTimer()
    Set CallBackRef = Nothing
    Application.OnTime NextTick, "TickTock", , False
End Sub

In your userform:

Option Explicit

Private Const NumberOfSeconds = 1 'every second

Private Sub UserForm_Initialize()
    data.Enabled = True
    hora.Enabled = True
    StartTimer Me, NumberOfSeconds
End Sub

Private Sub UserForm_Terminate()
    StopTimer
End Sub

Public Sub Timer()
    data = Date
    hora = Time
End Sub