VBA error handling

[TomCon]

How do you set up to handle an error within an error handler?

Here is what i want to do. I try this statement. If it works, i'm done.
Set wbDest = Workbooks(Dest)

If it fails I want to go to an error handler that tries to open the file:
Workbooks.Open Filename:=dir_loc & Dest

And if that fails, i want to go to an error handler that creates the workbook:
Workbooks.Add
...

I paste the entire code below.

What is happening is that if the attempt to open the workbook errors, the VBA sub fails, and the ON ERROR GOTO just before that statement seems to be ignored.

How is this case property set up to work?

Sub Init_Books()
Src = "D4_p_TRK.xlsm"
Dest = "D4p_new4.xlsm"
Set wbSrc = Workbooks(Src)
On Error GoTo needopen
Set wbDest = Workbooks(Dest)
GoTo end_sub

needopen:
dir_loc = "C:\Users\xxxx\Documents\"
On Error GoTo create_it
ChDir dir_loc
Workbooks.Open Filename:=dir_loc & Dest 'Why does this not get handled by the "On Error GOTO create_it" statement?
Resume

create_it:
Workbooks.Add

ActiveWorkbook.SaveAs Filename:=dest_loc & Dest _
, FileFormat:=xlOpenXMLWorkbookMacroEnabled, CreateBackup:=False
Resume

end_sub:
End Sub

 

[Yongle]

You have asked for new workbook to created and saved as the 3rd option.
That is what this does

    Dim Dest As String, dir_loc As String, wbDest As Workbook, fPath As String
    Dest = "filename.xlsm"
    dir_loc = "C:\whatever\"
    fPath = dir_loc & Dest

    On Error Resume Next
    Set wbDest = Workbooks(Dest)
    If Err.Number <> 0 Then
        If Dir(fPath) <> "" Then
            Workbooks.Open (fPath)
        Else
            Set wbDest = Workbooks.Add
            wbDest.SaveAs Filename:=fPath, FileFormat:=xlOpenXMLWorkbookMacroEnabled, CreateBackup:=False
        End If
    End If
    On Error GoTo 0

Do you want the previously active workbook saved as Dest?
Do you want the original workbook saved first and then re-saved as Dest?

 

[TomCon]

Wow, perfect, thanks!!! I do not need the previously active WB saved or anything re-saved. The macro does exactly what i need to be done.

And i learned about the Dir() function which was very useful in this context (and may be in the future for me!), as well as a better way to handle the Error Handling.

Thanks again for your time!

 

[Yongle]

Thanks for your feedback