VBA for printing select range with page formatting

[FutureJack031]

Good morning,

I'm looking for a VBA code that will print a select range of cells on the active sheet and will format the printed sheet to fit everything on 1 page in portrait orientation.

Any direction will be much appreciated.

Thanks
DV

 

[Logit]

Sub btnPrint_Click()


    Dim rng As Range


    Set rng = Selection
    rng.Select
    
    With rng.Worksheet
      'Do a crude assignment of paper orientation
      If rng.Height > rng.Width Then
      .PageSetup.Orientation = xlPortrait
      Else
        .PageSetup.Orientation = xlLandscape
      End If
      .PageSetup.PrintArea = rng.Address
      
      .PrintOut Preview:=True, IgnorePrintAreas:=False
      
    End With


End Sub

 

[Domenic]

Try...

Option Explicit

Sub PrintSelectedRange()


    If TypeName(Selection) <> "Range" Then
        MsgBox "Please select a range of cells, and try again!", vbExclamation
        Exit Sub
    End If
    
    Application.PrintCommunication = False
    With ActiveSheet.PageSetup
        .Orientation = xlPortrait
        .FitToPagesWide = 1
        .FitToPagesTall = 1
    End With
    Application.PrintCommunication = True
    
    Selection.PrintOut Copies:=1
    
End Sub