VBA Function to Highlight MATCHES

[Haziyama]

Hello everyone,
It has been a week since I am looking to do a function which highlights all matches between two different sheets.
It compares from a value from the first one to whole column from the second and it highlights the match in the first one.
I am still new to coding in VBA and I got confused how to do it by myself.
So can any one help me doing this, please?

Here is my code until now:


Sub searching ()
LastL = ActiveSheet.UsedRange.Rows.Count
CurrentL = 2

While CurrentL <= LastL
If Worksheets("HP").Range("C" & CurrentL).Value = Worksheets("Client non connectés").Range("B:B").Value Then
Worksheets("Client non connectés").Range("B" & CurrentL).Interior.Color = 65535
End If
CurrentL = CurrentL + 1



'Wend
End sub

 

[Fluff]

Hi & welcome to MrExcel.
How about

Sub Haziyama()
   Dim Cl As Range
   Dim Dic As Object
   
   Set Dic = CreateObject("scripting.dictionary")
   Dic.CompareMode = 1
   With Sheets("HP")
      For Each Cl In .Range("C2", .Range("C" & Rows.count).End(xlUp))
         Dic.Item(Cl.Value) = Empty
      Next Cl
   End With
   With Sheets("Client non connectés")
      For Each Cl In .Range("B2", .Range("B" & Rows.count).End(xlUp))
         If Dic.Exists(Cl.Value) Then Cl.Interior.Color = 65535
      Next Cl
   End With
End Sub