-
If you would like to post, please check out the MrExcel Message Board FAQ and register here. If you forgot your password, you can reset your password.
vba help - Outlook email on button click with Table
- Thread starter Mallesh23
- Start date
Hello guys,
I'm very new as a registered user here, but I've been a fan of this forum for a while.
I have pretty much the same question as Mallesh23 above and would appreciate any answers.
Thanks,
Patrick
I'm very new as a registered user here, but I've been a fan of this forum for a while.
I have pretty much the same question as Mallesh23 above and would appreciate any answers.
Thanks,
Patrick
Upvote
0
smozgur
BatCoder
- Joined
- Feb 28, 2002
- Messages
- 2,537
Since this is an Excel forum, and the actual question can be actually answered in Outlook by using templates easily without using VBA (which should be asked in General Discussion & Other Applications forum), I will provide a VBA macro that will run in Excel to create an email message which contains a blank table.
It is done by using the
Make sure including Microsoft Outlook XX Object Library in VBE->Tools->References, or late binding can be also used with the
It is done by using the
.HTMLBody property of Outlook.MailItem object.Make sure including Microsoft Outlook XX Object Library in VBE->Tools->References, or late binding can be also used with the
CreateObject method.
VBA Code:
Sub newEmailWithTable()
Dim olApp As Outlook.Application
Dim olMessage As Outlook.MailItem
Dim strHtmlTable As String
Dim i As Integer
Dim j As Integer
Dim intCols As Integer
Dim intRows As Integer
Dim strSubject As String
Dim strColHeader As String
' Setting variables
' These variables can be passed as macro variables
' by setting the sub routine to include them
' this way the macro can be reused
intCols = 4
intRows = 10
strSubject = "Subject goes here"
strColHeader = "Test"
' Create Outlook session
Set olApp = New Outlook.Application
' Create new Outlook mail item
Set olMessage = olApp.CreateItem(olMailItem)
With olMessage
.Subject = strSubject
' Start building HTML code
' Style properties can be defined here
' Look at the existing CSS properties for table, th, and td elements
strHtmlTable = "<html>" & _
"<head>" & _
" <style>" & _
" table {border: 1px solid #ccc;}" & _
" td, th {border: 1px solid #ccc;width: 100px; height: 20px;padding: 0px}" & _
" </style>" & _
"</head>" & _
"<body>" & _
" <table cellspacing=""0"" cellpadding=""0"">" & _
" <thead>" & _
" <tr>"
' Set up column headers
For j = 1 To intCols
strHtmlTable = strHtmlTable & _
" <th>" & strColHeader & j & "</th>"
Next j
' End of table head, thead, element
strHtmlTable = strHtmlTable & _
" </tr>" & _
" </thead>"
' Table rows
For i = 1 To intRows
strHtmlTable = strHtmlTable & "<tr>"
' Table columns
For j = 1 To intCols
strHtmlTable = strHtmlTable & "<td></td>"
Next j
strHtmlTable = strHtmlTable & "</tr>"
Next i
' Finalize table
strHtmlTable = strHtmlTable & _
" </table>" & _
"</body>" & _
"</html>"
' Set the HTMLBody property of the mail item
.HTMLBody = strHtmlTable
' Display the message window
.Display
End With
End Sub
Upvote
0
Similar threads
- Question
- Solved
