VBA let user choose multiple sheets in workbook from list and copy to new workbook

[Want2BExcel]

I found this answer from JohnnyL in this post VBA - Allow User to Select Which Worksheet to Copy
Its's almost what I need

Sub ChooseSheetNumberToUse()                                                                        ' select a sheet to copy
'
    Dim UserSelectedSheet       As String
'
    Worksheets(1).Activate                                                                          ' Had to add this to allow the sheet selected to work
'
    MsgBox "In the next popup window, Click the sheet name " & vbCrLf & "that you would like to copy." ' Advise user what to do next
'
    If Application.CommandBars("workbook tabs").Controls(16).Caption Like "More Sheets*" Then       ' This CommandBars only shows up to 16 sheets, after that it
'                                                                                                       will display the first 15 sheets and the 16th item will be
'                                                                                                       an option of "More Sheets..." which will give full list
        Application.CommandBars("workbook tabs").Controls(16).Execute                               ' If more than 16 sheets are found, click the "More Sheets ..."
    Else                                                                                            ' Otherwise ...
        Application.CommandBars("Workbook Tabs").ShowPopup 800, 300                                 '   Display the sheets found
    End If
'
    UserSelectedSheet = ActiveSheet.Name                                                            ' Save the sheet name that the user selected
    Debug.Print UserSelectedSheet                                                                   ' Test print, for verification, name of user selected sheet
'
'   The variable 'UserSelectedSheet' now contains the sheet name selected by the user
'
'
'   Add desired additional coding here ...
'
End Sub

Is it possible to choose multiple sheets and not only one from Application.CommandBars("Workbook Tabs").ShowPopup 800, 300? And then save them all to a new workbook? The new workbook should stay active. So it easy to save it immediately to a path.
....well it could be cool to write that path in the code also....along with filename based on a fixed string like "Schedule" and the value in two cells B1 and E1

 

[davesexcel]

Create a userform an insert a listbox and button
Just place the Listbox1 on the userform, don't do anything with it. The code will populate the listbox.

place this code in the userform module.

Private Sub CommandButton1_Click()
    Dim i As Integer, sht As String, arr() As String, n As Long
   
    For i = 0 To ListBox1.ListCount - 1
        If ListBox1.Selected(i) = True Then
            ReDim Preserve arr(n)
            arr(n) = ListBox1.List(i)
            n = n + 1
        End If
    Next i
    Sheets(arr).Copy
    Unload Me
End Sub

Private Sub UserForm_Initialize()
    With ListBox1
        For sh = 1 To Sheets.Count
            .AddItem ActiveWorkbook.Sheets(sh).Name
        Next sh
        .MultiSelect = 1
    End With
End Sub

When the userform shows, select the sheets you want in a new workbook and click the button.

 

[Want2BExcel]

Create a userform an insert a listbox and button
Just place the Listbox1 on the userform, don't do anything with it. The code will populate the listbox.

View attachment 71516

place this code in the userform module.

Private Sub CommandButton1_Click()
    Dim i As Integer, sht As String, arr() As String, n As Long
  
    For i = 0 To ListBox1.ListCount - 1
        If ListBox1.Selected(i) = True Then
            ReDim Preserve arr(n)
            arr(n) = ListBox1.List(i)
            n = n + 1
        End If
    Next i
    Sheets(arr).Copy
    Unload Me
End Sub

Private Sub UserForm_Initialize()
    With ListBox1
        For sh = 1 To Sheets.Count
            .AddItem ActiveWorkbook.Sheets(sh).Name
        Next sh
        .MultiSelect = 1
    End With
End Sub

When the userform shows, select the sheets you want in a new workbook and click the button.

IT's BEAUTIFUL Took me a while, to figure out everything regarding creating and implementing a userform. This was my first...but definitely not my last
Thank you davesexcel