VBA not breaking but not working

[Vally 88]

Hello All,

I'm trying to create a Hide- show VBA based on *name* for different tabs. Please find code below:

Sub hide_Arabic_tabs()


    For Each ws In ActiveWorkbook.Worksheets
        On Error Resume Next
        Select Case True
            Case LCase(ws.Name) Like "*Arabic*"
            ws.Visible = xlSheetHidden
            Case Else
        End Select
    Next ws


End Sub
Sub show_Arabic_tabs()


    For Each ws In ActiveWorkbook.Worksheets
        On Error Resume Next
        Select Case True
            Case LCase(ws.Name) Like "*Arabic*"
            ws.Visible = xlSheetVisible
            Case Else
        End Select
    Next ws
    End Sub

I have 18 of them in a module and they are linked to a button. I'm sure the VBA is correct since I'm currently using it with other name conditions in other module, eg below:

Sub hide_raw_tabs()


    For Each ws In ActiveWorkbook.Worksheets
        On Error Resume Next
        Select Case True
            Case LCase(ws.Name) Like "*raw*"
            ws.Visible = xlSheetHidden
            Case Else
        End Select
    Next ws


End Sub
Sub show_raw_tabs()


    For Each ws In ActiveWorkbook.Worksheets
        On Error Resume Next
        Select Case True
            Case LCase(ws.Name) Like "*raw*"
            ws.Visible = xlSheetVisible
            Case Else
        End Select
    Next ws
    End Sub

It's probably worth saying that the 2 macros can affect the same sheet, so to make it clear I have a tab called Arabic Raw Data. I want this one showing or hiding with both macros "*raw*" and "*Arabic*". Unfortunately my macros based on languages are running (not breaking) but not working while raw is working perfectly. Anyone has any clue why? I have tried to have them in a unique module as well as 2 different ones but it'snot making any difference.

Hope any of you got a better idea thank you in advance!!!

Valeria

 

[FormR]

Hi, welcome to the forum!

Case LCase(ws.Name) Like "*Arabic*

LCase() is returning the sheet name in lower case, so your comparison text (red above) also needs to be in lower case.

 

[PatOBrien198]

just a guess....

Case LCase(ws.Name) Like "*Arabic*"
perhaps should be:
Case LCase(ws.Name) Like "*arabic*"

 

[Fluff]

Hi, the problem is that you are looking at the lowercase of worksheet.name, but comparing it to Arabic which is not lowercase. change Arabic to arabic & you should be ok

 

[Vally 88]

thank you very much all of you!!

this was the case, I'm stupid I didn't think about it!!!

Cheers!!!!

 

[RoryA]

Welcome to the forum.

You can streamline your code a lot by refactoring into one routine that takes a sheet name to compare and an option to hide or show the tabs, like this:

Sub hide_Arabic_tabs()
    tabsVisible "Arabic", False
End Sub
Sub show_Arabic_tabs()
    tabsVisible "Arabic", True
End Sub
Sub hide_raw_tabs()
    tabsVisible "raw", False
End Sub
Sub show_raw_tabs()
    tabsVisible "raw", True
End Sub
Sub tabsVisible(sName As String, Optional bVisible As Boolean = True)
    Dim ws As Worksheet
    sName = LCase$(sName)
    For Each ws In ActiveWorkbook.Worksheets
        On Error Resume Next
        If LCase(ws.Name) Like "*" & sName & "*" Then
            If bVisible Then
                ws.Visible = xlSheetVisible
            Else
                ws.Visible = xlSheetHidden
            End If
        End If
    Next ws

End Sub

 

[Vally 88]

Cheers!
I'll defo try this!