VBA to copy dynamic row data from multiple sheets with static column data into one sheet within the same workbook

[Chestnuttgirl98]

I've searched the forum and google and cannot find quite what i'm looking for.

I have a template for data that i need to collect from 6 individual teams within my organization. The columns are exactly the same for each team, and each team's data is represented in individual tabs/sheets. I need to combine each of the individual team's data into one master sheet (called AutoCombined). However, each team may have entered different amounts of data (rows).

How do I only copy each sheet's data (and not the header information) when the range of rows with data is dynamic? Each sheet's range will start at A2, but will end anywhere in column AD.
How do I create a macro to copy and paste each sheet's data into a master sheet, thereby having each subsequent data set paste directly after the previous one copied in order to have one continuous table of the combined data?

Current information on team data, and columns A through AD share the same header names
Team 1 has 88 rows of data
Team 2 has 92 rows of data
Team 3 has 52 rows of data
Team 4 has 53 rows of data
Team 5 has 132 rows of data
Team 6 has 28 rows of data

I need a master sheet (called AutoCombined, with headers pre-populated in row 1) with all 445 rows of data accounted for, and each time a team updates their sheet with additional data, I need to be able to automatically update the master sheet without manually copying and pasting each time.

 

[Chestnuttgirl98]

To get values only, use

Sub Chestnuttgirl()
   Dim Ws As Worksheet
   Dim Rng As Range
  
   With Sheets("AutoCombined")
      If .Range("A2") <> "" Then .Range("A2:AD" & .Range("A" & Rows.Count).End(xlUp).Row).ClearContents
      For Each Ws In Worksheets
         If Ws.Name Like "Team*" Then
            Set Rng = Ws.Range("A2:AD" & Ws.Range("A" & Rows.Count).End(xlUp).Row)
            .Range("A" & Rows.Count).End(xlUp).Offset(1).Resize(Rng.Rows.Count, Rng.Columns.Count).Value = Rng.Value
         End If
      Next Ws
   End With
End Sub

Honest to goodness, can't thank you enough for helping me. Very much appreciated!

 

[Fluff]

You're welcome & thanks for the feedback