VBA to count numbers between columns

[aaaaa34]

Hello guys,
I'd like to ask your help for VBA to count numbers between columns Q:Z columns in which rows have values more than three.
In the attached file, you will see there are three and more numbers in Rows no.3-4-9-11-12-13-15-17-18-21
I want to know these numbers how many times are written in these rows.
Please have a look into the attached file, you will see (desired) result in the worksheet.

File: Book1.xlsx (Click to "Download" in right-up corner of opened page)

Thank you so much for your interest.

 

[Fluff]

Ok, realised my mistake in the original, this will also cater for no rows having 3 or more values

Sub aaaa34()
   Dim Ary As Variant
   Dim r As Long, c As Long
   
   Ary = Range("Q2:Z" & Range("Q" & Rows.Count).End(xlUp).Row).Value2
   With CreateObject("scripting.dictionary")
      For r = 1 To UBound(Ary)
         If Ary(r, 3) <> "" Then
            For c = 1 To UBound(Ary, 2)
               If Ary(r, c) = "" Then Exit For
               .Item(Ary(r, c)) = .Item(Ary(r, c)) + 1
            Next c
         End If
      Next r
      If .Count > 0 Then Range("AB2").Resize(.Count, 2).Value = Application.Transpose(Array(.Keys, .Items))
   End With
End Sub

 

[aaaaa34]

yes, exactly, I found out it in this line, Fluff

   Ary = Range("Q2:Z" & Range("Q" & Rows.Count).End(xlUp)).Value2

I changed as "Q2:Z1000" and everything is fine now.
Thanks a lot CEO

 

[Fluff]

If you add the .row as shown in post#11 then it will work, regardless of how many rows of data you have.

 

[aaaaa34]

Ah your last edit is super cool
now everything is fine, Boss
Thank you, thanks a lot!!!!

 

[Fluff]

You're welcome & thanks for the feedback.