VBA to create a loop on specific column, then use the ActiveCell.Value in that specific column to filter a table of data

[Niggy Yeap]

HI ALL, I am currently creating a VBA macro to help my colleague to make their repetitive copy and paste work easier and faster.
So here's how my macro should work. Before I run a macro, I need to manually generate a column, that column contains a list of unique value Vendor Name.
This Vendor Name is originally from the table of data (the first row to be more specific).
The loop will look at this manually created column first, then it use the first value it gets to filter the whole table(this column does not have any header).
It will filter all the date in the table, using ActiveCell.Value as a Criteria1. This the drafted code I make. It won't work as I expexted, as help are appreciated.

Sub loop_filter()

Dim x As Integer
NumRows = Range("L2", Range("L2").End(xlDown)).Rows.Count
Range("L2").Select 'Select first data

For x = 1 To NumRows
Cells.Select
Selection.AutoFilter
ActiveSheet.Range("$A:$J").AutoFilter Field:=1, Criteria1:=NumRows.ActiveCell
Cells.Select
Selection.Copy
Workbooks.Add
ActiveSheet.Paste
Application.CutCopyMode = False
ActiveWorkbook.SaveAs Filename:= _
"C:\Users\Easy IT Team\Desktop\Test\" + NumRows.ActiveCell.Value + ".xlsx", FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
ActiveWindow.Close
ActiveCell.Offset(1, 0).Select
Next
End Sub

 

[Fluff]

Hi & welcome to MrExcel.
How about

Sub NiggyYeap()
   Dim Cl As Range
   Dim Ws As Worksheet
   
   Application.ScreenUpdating = False
   Set Ws = ActiveSheet
   Ws.Range("A1", Ws.Range("A" & Rows.Count).End(xlUp)).AdvancedFilter xlFilterCopy, , Range("L2"), True
   For Each Cl In Ws.Range("L3", Ws.Range("L" & Rows.Count).End(xlUp))
      Ws.Range("A1:J1").AutoFilter 1, Cl.Value
      Workbooks.Add
      Ws.AutoFilter.Range.Copy Range("A1")
      With ActiveWorkbook
         .SaveAs "C:\Users\Easy IT Team\Desktop\Test\" & Cl.Value & ".xlsx", 51
         .Close False
      End With
   Next Cl
   Ws.ShowAllData
End Sub

 

[Niggy Yeap]

Hi & welcome to MrExcel.
How about

Sub NiggyYeap()
   Dim Cl As Range
   Dim Ws As Worksheet
  
   Application.ScreenUpdating = False
   Set Ws = ActiveSheet
   Ws.Range("A1", Ws.Range("A" & Rows.Count).End(xlUp)).AdvancedFilter xlFilterCopy, , Range("L2"), True
   For Each Cl In Ws.Range("L3", Ws.Range("L" & Rows.Count).End(xlUp))
      Ws.Range("A1:J1").AutoFilter 1, Cl.Value
      Workbooks.Add
      Ws.AutoFilter.Range.Copy Range("A1")
      With ActiveWorkbook
         .SaveAs "C:\Users\Easy IT Team\Desktop\Test\" & Cl.Value & ".xlsx", 51
         .Close False
      End With
   Next Cl
   Ws.ShowAllData
End Sub

Thank You Fluff for the guidance, I'm glad that my mindset is same as yours. Yesterday, I use something like your suggestion and it works. Thank you for giving me the confidence that I am doing the right thing. Much Love and Much Thanks to you mate.

 

[Fluff]

You're welcome & thanks for the feedback.