VBA to highlight row based on a cell within row

[Guitarmageddon]

Hello all. Many thanks to @Fluff for getting me sorted in some other steps within this current macro.

I would like to add some VBA in at the end of my macro that does two different sets of highlights:
1.) highlight the entire row if the site number in Column M equals 60001 OR 70001. I want this DARK purple
2.) Highlight the entire row if the site number in column M equals 16001. I want this LIGHT purple.
I have given a quick example of some of the highlights below.

Notes:
My report length is dynamic, but you can reference column A since that will always go down to the end of the report
My number of columns extends out to AC, which I believe is 29 columns total on the report. If possible Id like to confine the highlight to that.

I had something similar in another macro I had (based on some unrelated values), but it was really hard for me to dissect and repurpose since I cant remember what I did! Id appreciate any help greatly here from the masters!

   Range("A2").Select
    Columns("l:l").ColumnWidth = 10.14
    Do While ActiveCell.Offset(0, 12) <> ""
       If ActiveCell.Offset(0, 12).FormulaR1C1 <> "000" Then
           Range(ActiveCell, ActiveCell.Offset(0, 42)).Select
               With Selection.Interior
                   .Pattern = xlSolid
                   .PatternColorIndex = xlAutomatic
                   .Color = 65535 'yellow
                   .TintAndShade = 0
                   .PatternTintAndShade = 0
               End With
       End If
       ActiveCell.Offset(1, 0).Select
       
    Loop

 

[Fluff]

You can modify the macro I supplied like

   With ActiveWorkbook.Sheets("Page1")
      For Each Cl In .Range("N9:N" & .Range("M" & Rows.Count).End(xlUp).Row)
         Cl.Value = Dic(Cl.Offset(, -1).Value)
         Select Case Cl.Offset(, -1).Value
            Case 60001, 70001
               Cl.Offset(, -12).Resize(, 29).Interior.Color = 10498160
            Case 16001
               Cl.Offset(, -12).Resize(, 29).Interior.Color = 16737996
         End Select
      Next Cl
   End With

 

[nemmi69]

This is probably better as it clears those that do not match.

Sub HighlightRows()
'1.) highlight the entire row if the site number in Column M equals 60001 OR 70001. I want this DARK purple
' 2.) Highlight the entire row if the site number in column M equals 16001. I want this LIGHT purple.

Dim lRow As Long
Dim RowLoop As Long


lRow = Cells(Rows.Count, "M").End(xlUp).Row

For RowLoop = 1 To lRow
    If Range("M" & RowLoop).Value = 60001 Or Range("M" & RowLoop).Value = 70001 Then
        'dark purple
         Rows(RowLoop & ":" & RowLoop).Interior.Color = 10498160
    ElseIf Range("M" & RowLoop).Value = 16001 Then
        'light purple
        Rows(RowLoop & ":" & RowLoop).Interior.Color = 16737996
    Else
        Rows(RowLoop & ":" & RowLoop).Interior.Pattern = xlNone
    End If

Next RowLoop

End Sub

 

[Guitarmageddon]

One small modification @nemmi69

If I wanted the dark purple to be this

    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .ThemeColor = xlThemeColorAccent4
        .TintAndShade = 0.399975585192419
        .PatternTintAndShade = 0
    End With

And the light purple to be this

    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .ThemeColor = xlThemeColorAccent4
        .TintAndShade = 0.799981688894314
        .PatternTintAndShade = 0
    End With

How do I do that? I couldnt figure out the straight color code for them, so I just make a quick macro and selected the color preset in the fills menu, and that was the code for those colors.....

 

[Fluff]

The dark purple is 13082801
and the light is 15523812

 

[Guitarmageddon]

The dark purple is 13082801
and the light is 15523812

Can you share how you found that?

 

[Fluff]

I ran your code & then in the Immediate window i put ?activecell.Interior.Color& pressed enter.
Then ran the other ode & did the same