VBA to lock each worksheet in a workbook

[XLBob]

I have below code to protect each sheet in a workbook. However when I run this, it only protects the first one. The for loop doesn't work for some reason. Anyone knows why?

Sub Macro1()
'
' Macro1 Macro
'

Dim sh As Worksheet
For Each sh In ActiveWorkbook.Worksheets
    Cells.Select
    Selection.Locked = False
    Selection.FormulaHidden = False
    Selection.SpecialCells(xlCellTypeFormulas, 23).Select
    Selection.Locked = True
    Selection.FormulaHidden = False
    ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True _
        , AllowSorting:=True, AllowUsingPivotTables:=True, Password:="123"
    ActiveSheet.EnableSelection = xlUnlockedCells
  
Next sh
End Sub

 

[RoryA]

Your code locks the active sheet, but never activates any sheet. However you don't need to activate any if you use this:

Sub Macro1()
'
' Macro1 Macro
'

Dim sh As Worksheet
For Each sh In ActiveWorkbook.Worksheets
   With sh.Cells
    .Locked = False
    .FormulaHidden = False
    On Error Resume Next
    with .SpecialCells(xlCellTypeFormulas, 23)
      .Locked = True
      .FormulaHidden = False
    end with
    On Error goto 0
   end with
   sh.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True _
        , AllowSorting:=True, AllowUsingPivotTables:=True, Password:="123"
    sh.EnableSelection = xlUnlockedCells
  
Next sh
End Sub

 

[XLBob]

tried that. got error "Object Required"

 

[RoryA]

On which line? It shouldn't be possible given the error handler unless you have set your VB Editor to break on all errors and you don't have any formulas on one of the sheets.