VBA to set print to default

[kgkev]

I have an application that prints to PDF then needs to print to the default printer.

Is there any way to identify what the default printer is and then ensure it prints to this printer?

I can't be sure that the activeprinter at the start of the job will be the default so this isn't really an option.

 

[jim may]

This might help...

http://www.ozgrid.com/forum/showthread.php?t=50637&page=1

 

[kgkev]

I can't be sure that the activeprinter at the start of the job will be the default so this isn't really an option.

Thanks - I had already explorered that route but when starting the macro I cannot be sure that the last printer was the default.

 

[RoryA]

Here are a few methods to get the default printer name:

Declare Function GetTheDefaultPrinter Lib "winspool.drv" Alias "GetDefaultPrinterA" _
                                      (ByVal sPrinterName As String, lPrinterNameBufferSize As Long) As Long
Function GetDefaultPrinter() As String
   ' using API above
   Dim DefPrinter As String, sLen As Long, hResult As Long
   DefPrinter = Space$(255)
   sLen = 255
   hResult = GetTheDefaultPrinter(ByVal DefPrinter, sLen)
   If hResult <> 0 Then GetDefaultPrinter = Left(DefPrinter, sLen - 1)
End Function
Function GetDefaultPrinter2() As String
   ' Using WMI
   Dim scomputer As String
   Dim oWMIService, colPrinters, oItem
   scomputer = "."
   Set oWMIService = GetObject("winmgmts:\\" & scomputer & "\root\cimv2")
   Set colPrinters = oWMIService.ExecQuery("Select * from Win32_Printer", , 48)
   For Each oItem In colPrinters
      If (oItem.Attributes And 4) = 4 Then
         GetDefaultPrinter2 = oItem.Name
         Exit For
      End If
   Next
End Function
Function GetDefaultPrinter3() As String
   ' Using Shell and registry
   Set oShell = CreateObject("WScript.Shell")
   sRegVal = "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows\Device"
   sDefault = ""
   On Error Resume Next
   sDefault = oShell.RegRead(sRegVal)
   sDefault = Left(sDefault, InStr(sDefault, ",") - 1)
   On Error GoTo 0
   GetDefaultPrinter3 = sDefault
End Function

 

[RoryA]

If you need the port as well (which you probably do here) then you can use this variation of the third function:

Function GetDefaultPrinter3() As String
   ' Using Shell and registry
   ' output includes port
   Dim oShell, varData
   Dim sRegVal As String, sDefault As String
   Set oShell = CreateObject("WScript.Shell")
   sRegVal = "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows\Device"
   sDefault = ""
   On Error Resume Next
   sDefault = oShell.RegRead(sRegVal)
   varData = Split(sDefault, ",")
   sDefault = varData(0) & " on " & varData(2)
   On Error GoTo 0
   GetDefaultPrinter3 = sDefault
End Function

 

[kgkev]

thanks rorya,

Just running through and getdefaultprinter3 falls over as oShell is not declared.

What type of variable is it?


Edit - no variavles are defined - Can you confirm them all please

 

[RoryA]

See my last post. (the code was from my VBS samples, hence no declarations)

 

[kgkev]

Function GetDefaultPrinter3() As String
   ' Using Shell and registry
   ' output includes port
   Dim oShell, varData
   Dim sRegVal As String, sDefault As String
   Set oShell = CreateObject("WScript.Shell")
   sRegVal = "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows\Device"
   sDefault = ""
   On Error Resume Next
   sDefault = oShell.RegRead(sRegVal)
   varData = Split(sDefault, ",")
   sDefault = varData(0) & " on " & varData(2)
   On Error GoTo 0
   GetDefaultPrinter3 = sDefault
End Function

That is spot on - thanks!!