VLOOKUP using a range with reference in a cell

[bailey537]

I want to be able to change the range my vlookup equation looks at depending on a value found in a cell. I.e 2008 looks in the 2008 range, 2009 in the 2009 range. Or if it would be easier a double vlookup

my ranges look like the following

2007, 1 , 100
2007, 2 ,150
2007, 3 , 200
2007, 4 , 250
2008, 1 , 125
2008, 2, 130
2008, 3, 165
2008, 4, 190

at the moment 07 and 08 are different named ranges

 

[jc.021286]

Hi there,

From the sounds of it you are using named ranges for your VLOokup. If so and you want to effectuate this, you would need to use the indirect function to pull at information. So if in Cells D1, you have your named range you want to look into and E1 your search value, your Vlookup would be =vlookup(E1,Indirect(D1),2, False).

Hope this helps
jc

 

[Sandeep Warrier]

Hi

Do you mean something like

Excel Workbook
	A	B	C	D	E	F	G	H
1	Range	Lookup Val	Return Val			Range	Lookup Val	Return Val
2	2007	1	100			2007	2	150
3	2007	2	150
4	2007	3	200
5	2007	4	250
6	2008	1	125
7	2008	2	130
8	2008	3	165
9	2008	4	190
Sheet1

Excel 2003

Cell Formulas
Range	Formula
H2	=VLOOKUP(G2,OFFSET(INDEX($A$2:$A$9,MATCH(F2,$A$2:$A$9,0)),0,1,COUNTIF($A$2:$A$9,F2),2),2,0)

 

[mgirvin]

Following up on sandeep.warrier data set up:

Here is the data and formulas (formulas in green):

Excel Workbook
	A	B	C	D	E	F	G	H
1	Range	Lookup Val	Return Val	Join		Range	Lookup Val	Return Val
2	2007	1	100	20071		2008	2	130
3	2007	2	150	20072
4	2007	3	200	20073
5	2007	4	250	20074
6	2008	1	125	20081
7	2008	2	130	20082
8	2008	3	165	20083
9	2008	4	190	20084
Sheet1

Excel 2010

Here is the formula in cell D2 (copied down):

=A2&B2

Here is the formula in cell H2:

=INDEX(C2:C9,MATCH(F2&G2,D2:D9,0))

 

[mgirvin]

If you don't mind using Ctrl + Shift + Enter to put the formula into the cell, try this:

Here is the data and formula (formula in green):

Excel Workbook
	A	B	C	D	E	F	G	H
1	Range	Lookup Val	Return Val			Range	Lookup Val	Return Val
2	2007	1	100			2007	1	100
3	2007	2	150
4	2007	3	200
5	2007	4	250
6	2008	1	125
7	2008	2	130
8	2008	3	165
9	2008	4	190
Sheet1 (2)

Excel 2010

Then in cell H2 enter this formula with Ctrl + Shift + Enter:

=INDEX(C2:C9,MATCH(F2&G2,A2:A9&B2:B9,0))

 

[bosco_yip]

Using Mike Gel Girvin's table

Herein a database function solution :

H2, formula (one of) :

=DSUM(A1:C9,H1,F1:G2)

=DSUM(A1:C9,3,F1:G2)

=DGET(A1:C9,H1,F1:G2)

=DGET(A1:C9,3,F1:G2)

Regards