Want to make recorded macro code simple

[Sufiyan97]

I want to make below recorded macro code simple and short

Sub Default()
'
' Default Macro
'

'
    Range("B3:F50").Select
    With Selection.Interior
        .Pattern = xlNone
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
    Selection.Borders(xlDiagonalDown).LineStyle = xlNone
    Selection.Borders(xlDiagonalUp).LineStyle = xlNone
    With Selection.Borders(xlEdgeLeft)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlInsideVertical)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlInsideHorizontal)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Font
        .Name = "Calibri"
        .Size = 10
        .Strikethrough = False
        .Superscript = False
        .Subscript = False
        .OutlineFont = False
        .Shadow = False
        .Underline = xlUnderlineStyleNone
        .TintAndShade = 0
        .ThemeFont = xlThemeFontMinor
    End With
    With Selection.Font
        .Name = "Calibri"
        .Size = 10
        .Strikethrough = False
        .Superscript = False
        .Subscript = False
        .OutlineFont = False
        .Shadow = False
        .Underline = xlUnderlineStyleNone
        .TintAndShade = 0
        .ThemeFont = xlThemeFontMinor
    End With
    With Selection.Font
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
    End With
    Range("A2").Select
    ActiveCell.FormulaR1C1 = "=TODAY()"
    Range("A3").Select
    ActiveCell.FormulaR1C1 = "=TEXT(R[-1]C,""dddd"")"
    Range("A2:A3").Select
    Selection.Copy
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Range("G1").Select
    Application.CutCopyMode = False
    ActiveCell.FormulaR1C1 = "My Text"
    Range("M15").Select
End Sub

 

[GWteB]

The short version looks like ...

Sub Sufiyan97()

    With Range("B3:F50")

        With .Interior
            .Pattern = xlNone
            .TintAndShade = 0
            .PatternTintAndShade = 0
        End With

        .Borders(xlDiagonalDown).LineStyle = xlNone
        .Borders(xlDiagonalUp).LineStyle = xlNone

        With .Borders
            .LineStyle = xlContinuous
            .ColorIndex = 0
            .TintAndShade = 0
            .Weight = xlThin
        End With

        With .Font
            .ColorIndex = xlAutomatic
            .Name = "Calibri"
            .Size = 10
            .Strikethrough = False
            .Superscript = False
            .Subscript = False
            .OutlineFont = False
            .Shadow = False
            .Underline = xlUnderlineStyleNone
            .TintAndShade = 0
            .ThemeFont = xlThemeFontMinor
        End With
    End With

    Range("A2").Formula = Date
    Range("A3").Formula = Format(Date, "dddd")
    Range("G1").Value = "My Text"
End Sub

 

[Joe4]

The Macro Recorder is very literal, and records each cell selection.
In VBA, you usually don't really need to select range before working with it,
So most cases where one line ends "Select" and the next line begins with "Selection" can be combined into one, like GWteB did.

Not only is it shorter, but removing the "Select" statements will also help to speed up your code.

 

[Sufiyan97]

The short version looks like ...

Sub Sufiyan97()

    With Range("B3:F50")

        With .Interior
            .Pattern = xlNone
            .TintAndShade = 0
            .PatternTintAndShade = 0
        End With

        .Borders(xlDiagonalDown).LineStyle = xlNone
        .Borders(xlDiagonalUp).LineStyle = xlNone

        With .Borders
            .LineStyle = xlContinuous
            .ColorIndex = 0
            .TintAndShade = 0
            .Weight = xlThin
        End With

        With .Font
            .ColorIndex = xlAutomatic
            .Name = "Calibri"
            .Size = 10
            .Strikethrough = False
            .Superscript = False
            .Subscript = False
            .OutlineFont = False
            .Shadow = False
            .Underline = xlUnderlineStyleNone
            .TintAndShade = 0
            .ThemeFont = xlThemeFontMinor
        End With
    End With

    Range("A2").Formula = Date
    Range("A3").Formula = Format(Date, "dddd")
    Range("G1").Value = "My Text"
End Sub

Thank you very much GWteB, Works perfect and faster.

The Macro Recorder is very literal, and records each cell selection.
In VBA, you usually don't really need to select range before working with it,
So most cases where one line ends "Select" and the next line begins with "Selection" can be combined into one, like GWteB did.

Not only is it shorter, but removing the "Select" statements will also help to speed up your code.

as I don't know how to write VBA codes I generally prefer Macro recording for small repetitive tasks,

and Yes now GWteB code works faster.

 

[Joe4]

as I don't know how to write VBA codes I generally prefer Macro recording for small repetitive tasks,

What I provided was a "quick little tip" on how to make recorded code shorter and a little more efficient.
Make minor edits to recorded VBA code is a good way to get started in understanding and writing your own VBA.

 

[Sufiyan97]

What I provided was a "quick little tip" on how to make recorded code shorter and a little more efficient.
Make minor edits to recorded VBA code is a good way to get started in understanding and writing your own VBA.

Yes, I understand it.
I will try to edit recorded macros now onwards