Whatever is in Cell B6

[RLPeloquin]

This code works great but there is one exception that would make it perfect. Is there a way to Send whatever Email address is in B6 simply by clicking on Cell "B6". Which in this code is, With OutMail .To = "somebody@somewhere" This email address will always change but it will always be in Cell "B6". Thanks in advance!
Sub Send_Email()
Dim OutApp As Object, OutMail As Object, rng As Range
Set rng = Range("A1:N38")
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
With OutMail
.To = "somebody@somewhere"
.Subject = "Electricity Usage"
.HTMLBody = RangetoHTML(rng)
.Display
End With

End Sub

Function RangetoHTML(rng As Range)
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook
TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial xlPasteValues, , False, False
.Cells(1).PasteSpecial xlPasteFormats, , False, False
.Cells(1).Select
Application.CutCopyMode = False
On Error Resume Next
.DrawingObjects.Visible = True
.DrawingObjects.Delete
On Error GoTo 0
End With
With TempWB.PublishObjects.Add( _
SourceType:=xlSourceRange, _
Filename:=TempFile, _
Sheet:=TempWB.Sheets(1).Name, _
Source:=TempWB.Sheets(1).UsedRange.Address, _
HtmlType:=xlHtmlStatic)
.Publish (True)
End With
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center xublishsource=", "align=left xublishsource=")
TempWB.Close savechanges:=False
Kill TempFile

Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function

 

[Michael M]

Do you mean

With OutMail
.To = cells(6,2).value
.Subject = "Electricity Usage"
.HTMLBody = RangetoHTML(rng)
.Display
End With

 

[RLPeloquin]

Do you mean

With OutMail
.To = cells(6,2).value
.Subject = "Electricity Usage"
.HTMLBody = RangetoHTML(rng)
.Display
End With

Works like a charm. Thank you so much

 

[Michael M]

Glad to help...