What's wrong with this formula?

[zakasnak]

=IF(H733<100,"<100",IF(H733<300>100,">100<300",IF(H733<500>300,">300<500",IF(H733<1000>500,">500<1000",IF(H733<7500>1000,">1000<7500",IF(H733>7500,">7500",""))))))

It stops after<300>100.

 

[kkknie]

First of all, I'm not sure how H773<300>100 would even be interpreted. In general, you would need to use AND(H773<300,H773>100).

Even better, since this is a nested if, you can eliminate the greater than check (since if H773 was <100, it would never reach the second IF). You can also eliminate the last if. Can probably rewrite to:

=IF(H733<100,"<100",IF(H733<300,">100<300",IF(H733<500,">300<500",IF(H733<1000,">500<1000",IF(H733<7500,">1000<7500",">7500")))))

Also, you might want to think about using <= rather than <, since nothing will be returned if the value is 100, 300, 500 or 1000.

Hope this helps,

K

 

[zakasnak]

That worked, thanks so very much . . .

 

[gaj104]

I think your statement is quite long winded. Use an array lookup for a better solution:

Book1
	A	B	C	D
1	50	<100
2	100	>100<300
3	200	>100<300
4	350	>300<500
5	520	>500<1000
6	900	>500<1000
7	1120	>1000<7500
8	1500	>1000<7500
9	7000	>1000<7500
10	8000	>7500
Sheet1

Hope it helps

 

[dcardno]

A couple of things:
1) You can't test for "between" in that way: you need to test for the two conditions of ">100" and "<300" and also test that both conditions hold, either using an "and" function or multiplying the truth values. The formats are:

=if(and(H733>100),(H733<300)),"Between 100 & 300",next test...)

or

=if((H733>100)*(H733<300),"Between 100 & 300",next test...)

2) Once the formula starts evaluating past the first branch you know the value in H733 is greater than 100, so you don't need to evaluate it again. You can present this sort of logic as:

=if(H733 < 100,"Small Value",if(H733 < 300, "Between 100 & 300",If(H773 < 500,"Between 300 & 500",If(H733 < 7500, etc ....  ))))

3) Oftentimes, it is easier to write and (particularly) maintain such logic as a Lookup Table

 

[barry houdini]

=LOOKUP(H733,{0,100,300,500,1000,7500;"<100",">100<300",">300<500",">500<1000",">1000<7500",">7500"})

I'm assuming you only have positive values in H733......