Why is this EVENT not cancelling?

[mahmed1]

Hi All,

I have written this afterUpdate event

For some reason when i set the txtBal.setfocus it starts that event again but i thought the enable event would have cancell the event while it resets the focus

Thank You

Here is the code

Private Sub txtAmt_AfterUpdate()
    txtAmt = Format(txtAmt, "£#,##0.00")
    If txtBal.Value = "" Or txtAmt.Value = "" Then
        MsgBox "Both Balance and Amount fields need to be filled in to proceed further", vbOKOnly, "Update All Fields"
        Exit Sub
    ElseIf txtBal.Value < txtAmt.Value Then
        MsgBox "Balance has to be greater than Amount", vbOKOnly, "INVALID INPUT"
        txtBal.Value = ""
        txtAmt.Value = ""
        Application.EnableEvents = False
        txtBal.SetFocus
        Application.EnableEvents = True
        Exit Sub
    Else
        txtNoPmt = txtBal.Value / txtAmt.Value
    End If
End Sub

 

[RoryA]

EnableEvents doesn't affect controls on userforms (or most events for activex controls on a worksheet). You have to use your own control variable.

 

[mahmed1]

Sorry Rory how do i do this

Thank You

 

[RoryA]

For example:
At the top of the userform module, before any routines:

Dim bSkipEvents as Boolean

Your code then becomes:

Private Sub txtAmt_AfterUpdate()
   If bSkipEvents Then Exit Sub 
    txtAmt = Format(txtAmt, "£#,##0.00")
    If txtBal.Value = "" Or txtAmt.Value = "" Then
        MsgBox "Both Balance and Amount fields need to be filled in to proceed further", vbOKOnly, "Update All Fields"
        Exit Sub
    ElseIf txtBal.Value < txtAmt.Value Then
        MsgBox "Balance has to be greater than Amount", vbOKOnly, "INVALID INPUT"
        txtBal.Value = ""
        txtAmt.Value = ""
        bSkipEvents = True
        txtBal.SetFocus
        bSkipEvents = False
        Exit Sub
    Else
        txtNoPmt = txtBal.Value / txtAmt.Value
    End If
End Sub

 

[mahmed1]

ADVERTISEMENT

Thank you Rory

The event cancelling works but for some reason it is still not setting the focus to the txtBal textbox. It is skipping over it

 

[RoryA]

That's a timing issue. Your code does actually set the focus there but once the event code ends, the focus shifts to whichever control should have got the focus next based on the tab order of the form.

 

[mahmed1]

ADVERTISEMENT

Thank You

How can i get round this

 

[RoryA]

Either use a different event - preferably one that doesn't belong to either of those controls - or simply highlight the controls as invalid and pop up your message so the user knows to edit one or other of them.

 

[mahmed1]

Rory you have been a star

My mind has completely gone blank on me today. Is there any chance you could give an example of you mean by the above post #8

Thank YOu so much

 

[RoryA]

Instead of using SetFocus, simply change the Backcolor to say vbRed to indicate that it needs reviewing.