why message box shows in all of cases despite contain condition ?

[abdelfattah]

hi
I face problem is not clear for me . I put message in beggining of the code when textbox2 is empty , then pop up message "PLEASEE WRITE THE CODE" and if it's not .should continue the procedure and show the next message "Are you sure you want to delete variation?", vbCritical + vbYesNo , but the first message shows whether textbox2 is empty or not .

Private Sub CommandButton4_Click()
Dim lReply As Long
Dim ws As Worksheet
Dim strFind As String
If strFind = "" Then MsgBox "PLEASEE WRITE  THE CODE", vbExclamation
Exit Sub
 lReply = MsgBox("Are you sure you want to delete variation?", vbCritical + vbYesNo)
 If lReply = vbNo Then Exit Sub
 Set ws = Worksheets("sheet1")
 strFind = Me.TextBox2.Value
 
 With ws.UsedRange.Columns(2)
 If WorksheetFunction.CountIf(.Cells, strFind) <> 0 Then
 .Cells.Find(What:=strFind, After:=.Cells(1, 1), MatchCase:=True).EntireRow.Delete
 Else
 MsgBox "Could not find " & strFind & " on " & ws.Name, vbCritical
 Exit Sub
 End If
 End With
 
 
 strFind = "VO" & strFind
 On Error Resume Next
 Application.DisplayAlerts = False
 Sheets(strFind).Delete
 Application.DisplayAlerts = True
 On Error GoTo 0
 
 'Close Form
 Unload Me
End Sub

any help to fix it , please ?

 

[GWteB]

Replace this part ...

Dim strFind As String
If strFind = "" Then MsgBox "PLEASEE WRITE  THE CODE", vbExclamation

with this part:

Dim strFind As String
strFind = Me.TextBox2.Value
If strFind = "" Then MsgBox "PLEASEE WRITE  THE CODE", vbExclamation

 

[abdelfattah]

then it doesn't show the next message box

 

[GWteB]

then you should remove the next Exit Sub

Private Sub CommandButton4_Click()
Dim lReply As Long
Dim ws As Worksheet
Dim strFind As String
strFind = Me.TextBox2.Value
If strFind = "" Then MsgBox "PLEASEE WRITE  THE CODE", vbExclamation
Exit Sub
 lReply = MsgBox("Are you sure you want to delete variation?", vbCritical + vbYesNo)

 

[dmt32]

hi
I face problem is not clear for me . I put message in beggining of the code when textbox2 is empty , then pop up message "PLEASEE WRITE THE CODE" and if it's not but the first message shows whether textbox2 is empty or not .


any help to fix it , please ?

Hi,
try this update to your code & see if does what you want

Private Sub CommandButton4_Click()
    Dim lReply      As VbMsgBoxResult
    Dim ws          As Worksheet
    Dim strFind     As String
    
    strFind = Me.TextBox2.Value
    
    If Len(strFind) = 0 Then
        MsgBox "PLEASE WRITE  THE CODE", vbExclamation, "Entry Required"
        Me.TextBox2.SetFocus
        Exit Sub
    Else
        lReply = MsgBox("Are you sure you want To delete variation?", vbCritical + vbYesNo, "Confirm")
        If lReply = vbNo Then Exit Sub
    End If
    
    Set ws = Worksheets("sheet1")
    
    With ws.UsedRange.Columns(2)
        If WorksheetFunction.CountIf(.Cells, strFind) <> 0 Then
            .Cells.Find(What:=strFind, After:=.Cells(1, 1), MatchCase:=True).EntireRow.Delete
        Else
            MsgBox "Could Not find " & strFind & " On " & ws.Name, vbCritical, "Not Found"
            Exit Sub
        End If
    End With
    
    strFind = "VO" & strFind
    On Error Resume Next
    Application.DisplayAlerts = False
    Sheets(strFind).Delete
    Application.DisplayAlerts = True
    On Error GoTo 0
    
    'Close Form
    Unload Me
End Sub

Dave

 

[abdelfattah]

if I delete the exit sub will move to the next message . it doesn't make sense . because when the textbox2 is empty shows the first message and should exit sub (shouldn't happen any thing .it doesn't supposses to move next message) and if the textbox2 is not empty then should show the next message and continue the procedure .

 

[abdelfattah]

@dmt32 fantastic ! this what I want
thanks so much

 

[dmt32]

@dmt32 fantastic ! this what I want
thanks so much

welcome - glad we were able to resolve

appreciate the feedback

Dave