Will someone please make a macro for me?

[sherri77]

I am such a beginner that I can only do the 'record' macros , but I have promised to help someone and I find that I'm not able. Would you please write a macro for me since I have run out of time and have not been able to do it, even though I have really been trying? It is Excel 2003.

There are 5 columns, A-B-C and D always have data, E seldom has data. When column E does have data, the entire row needs to move to sheet 2 and the blank row left behind needs to be deleted. It would be good if the row would move on entering after typing in data. Also, there are already 100's of rows in this report, and if the macro could move all of those, that would be great.

Thank you so much!

 

[acw]

Sherri

This will copy across the existing data.

Sub ccc()
  Dim OutSH As Worksheet
  Set OutSH = Sheets("sheet2")
  For i = 2 To Cells(Rows.Count, 1).End(xlUp).Row
    If Not IsEmpty(Cells(i, 5)) Then Cells(i, 1).EntireRow.Copy Destination:=OutSH.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0)
  Next i
  For i = Cells(Rows.Count, 1).End(xlUp).Row To 2 Step -1
    If Not IsEmpty(Cells(i, 5)) Then Cells(i, 1).EntireRow.Delete
  Next i
End Sub

Can you be a bit more specific on the "trigger" for the auto move. Will it be the entry of data into a cell in column E?


Tony

 

[sherri77]

THANK YOU!

Tony

I appreciate what you've done so much! The macro works perfectly!
Yes, I think the trigger for the auto move would be when the curser leaves the cell in column E after the data has been entered.

You do really really good work! Thanks for saving my life !!

 

[acw]

Sherri

This worksheet_change event should get you going for the next part.

Private Sub Worksheet_Change(ByVal Target As Range)
  If Target.Cells.Count = 1 And Target.Column = 5 And Not IsEmpty(Target) Then
    Target.EntireRow.Copy Destination:=Sheets("sheet2").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0)
    Target.EntireRow.Delete
  End If
End Sub

Tony