Within Excel, use Windows Explorer to locate and paste a file path into cell A2

[jase71ds]

In another thread I asked about locating and pasting a folder path by using a Windows explorer type dialogue box.
gpeacock gave me this excellent code that works perfectly...

Sub GetFolder()
    Dim fdg As FileDialog
    Dim ifn As String
       With Application
           Set fdg = .FileDialog(msoFileDialogFolderPicker)
           ifn = .DefaultFilePath & .PathSeparator
       End With
       With fdg
          .InitialFileName = ifn
          .Title = "Select a location"
          .Show
       End With
    If fdg.SelectedItems.Count = 0 Then Exit Sub
    Range("A1").Value = fdg.SelectedItems(1)
 End Sub

But now, in addition to a folder, I also need the user to locate a file using a Windows explorer type dialogue box. The path of the file that the user locates needs to be pasted into A2.

I had thought I would be able to modify the above code to make finding a file (as opposed to a folder) and pasting the file path into A2 -- but alas, my VBA skills are just not there yet.

Could anyone assist?
Please note: I do not want to actually open the file that the user selects. Only paste the URL path into A2.

 

[JoeMo]

This will return the full path (i.e path and filename and extension) as well as just the path. Not sure which you want in A2 but you can easily adjust the code to place either in A2.

Sub FilePath()
Dim sFullPath As String, sPath As String
sFullPath = Application.GetOpenFilename
sPath = Mid(sFullPath, 1, InStrRev(sFullPath, "\") - 1)
Range("A2").Value = sPath
End Sub

 

[jase71ds]

Joe,
This is great!!
I modified it (as you said) to put:
sPath in A1
sFullPath in A2

Lastly, can you help me get just the file name in A3?
I'd be very grateful.

This is the code I have modified ever so slightly from you:

Sub FilePath()
Dim sFullPath As String, sPath As String
sFullPath = Application.GetOpenFilename
sPath = Mid(sFullPath, 1, InStrRev(sFullPath, "\") - 1)
Range("A1").Value = sPath
Range("A2").Value = sFullPath
End Sub

 

[JoeMo]

Joe,
This is great!!
I modified it (as you said) to put:
sPath in A1
sFullPath in A2

Lastly, can you help me get just the file name in A3?
I'd be very grateful.

This places the file name (including file extension) in A3 of the activesheet:

Sub FilePath()
Dim sFullPath As String, sPath As String
sFullPath = Application.GetOpenFilename
sPath = Mid(sFullPath, 1, InStrRev(sFullPath, "\") - 1)
Range("A1").Value = sPath
Range("A2").Value = sFullPath
Range("A3").Value = Right(sFullPath, Len(sFullPath) - InStrRev(sFullPath, "\"))
End Sub

 

[jase71ds]

Joe,

Thank you so much! I'll GLADLY buy you a beer if you ever come to Houston.
Your code does everything I need.

Again, thank you so very much!

Jase.