Worksheet_change event help

[PATSYS]

I have the below code

Private Sub worksheet_change(ByVal target As Range)

Dim rr As Integer
rr = target.Row

Application.EnableEvents = False

On Error Resume Next

If Not Intersect(target, Columns(1)) Is Nothing Then

    If target.Value = "" Then
        
        Cells(rr, 2).Value = ""

    Else

        Cells(rr, 2).FormulaR1C1 = _
        "=RC1+RC2"

    End If

Application.EnableEvents = True

End If

End Sub

What it does, as you know, is that when column A is deleted, it proceeds in deleting column B of the same row.

The problem is when the user deletes more than 1 row e.g. A2:A10. When the user does this, the code only deletes B2 but not B3:B10.

Is there a way to have the code delete the column B for all affected rows?

Thanks

 

[Jonmo1]

When more than 1 cell is changed at a time, then Target becomes a multiple cell range
A2:A10 in your example.

You can't use a line like
If target.Value = "" Then
When target is a multiple cell range.

You have to loop through each cell in the range..

hang on for example, accidentally hit submit before I was done...

 

[Jonmo1]

Try

Private Sub worksheet_change(ByVal target As Range)
Dim MyRange As Range, c As Range
Set MyRange = Intersect(target, Columns(1))
If MyRange Is Nothing Then Exit Sub
Application.EnableEvents = False
For Each c In MyRange
    If c.Value = "" Then
        Cells(c.Row, 2).Value = ""
    Else
        Cells(c.Row, 2).FormulaR1C1 = _
        "=RC1+RC2"
    End If
Next c
Application.EnableEvents = True
End Sub

 

[PATSYS]

Thanks Jonmo, that solves my problem.