Worksheet_SelectionChange

[Kathleen_0422]

I am using a worksheet event which will display and image when all required fields have entry:

It appears that the only way to fire the macro is when the user takes focus off the last cell. Is there a way I can have the image display even if the user is on the cell or a cell has been selected in the range as shown

<code>

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If ActiveSheet.Range("F7").Value <> "" And ActiveSheet.Range("F9").Value <> "" And ActiveSheet.Range("F11").Value <> "" And ActiveSheet.Range("F13").Value <> "" And ActiveSheet.Range("F15").Value <> "" And ActiveSheet.Range("F17").Value <> "" And ActiveSheet.Range("F19").Value <> "" And ActiveSheet.Range("F21").Value <> "" Then
Image1.Visible = True
Else
Image1.Visible = False
End If

End Sub

</code>
Column F has validation criteria

 

[Jerry Sullivan]

Hi Kathleen,

The code below will fire whenever your selection includes one of the cells
in your required range.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    On Error GoTo CleanUp
    Dim rngReqd As Range
    Set rngReqd = Range("F7,F9,F11,F13, F15, F17, F19, F21")
    If Intersect(rngReqd, Target) Is Nothing Then GoTo CleanUp
 
    Application.EnableEvents = False
 
    If Application.CountA(rngReqd) = rngReqd.Cells.Count Then
        Image1.Visible = True
    Else
        Image1.Visible = False
    End If
CleanUp:
    Application.EnableEvents = True
    Set rngReqd = Nothing
End Sub

Is there a way I can have the image display even if the user is on the cell or a cell has been selected in the range as shown

Not sure that I follow what you mean by "is on the cell"... do you mean if they change the value of one of the cells without moving to another cell?

If that is what your looking for, then Worksheet_Change would be a better event to use than Worksheet_SelectionChange. You can adapt the code above.