write macro to open a word document

[jakobt]

Want to write a VBA code to open a word document shored under S:\Book.Docx

 

[Domenic]

Here's an example where the code first checks whether Word is already running. If so, it assigns it to an object variable. If not, it starts Word and assigns it to an object variable. If it's not successful in starting Word, it exits the sub. Otherewise, it tries to open a Word document. If successful, it assigns it to another object variable. If not, it exits the sub.

Sub test()

    Dim wdApp As Object
    Dim wdDoc As Object
    
    On Error Resume Next
    Set wdApp = GetObject(, "Word.Application")
    If Err.Number <> 0 Then
        Err.Clear
        Set wdApp = CreateObject("Word.Application")
        If Err.Number <> 0 Then
            MsgBox "Unable to open Word!", vbExclamation
            Exit Sub
        End If
    End If
    On Error GoTo 0
    
    On Error Resume Next
    Set wdDoc = wdApp.documents.Open("c:\users\domenic\desktop\doc1.docx")
    If wdDoc Is Nothing Then
        MsgBox "Unable to open Word document!", vbExclamation
        Exit Sub
    End If
    On Error GoTo 0
    
    'Make Word visible
    wdApp.Visible = True
    
    'etc
    '
    '
    
    'Release objects from memory
    Set wdDoc = Nothing
    Set wdApp = Nothing
    
End Sub

Hope this helps!