writing to a cell current users name

[Joe C]

How do you write to a cell the current users login name?
I created a series of macros to allow users to update data from pivot table data and then rerun analysis. I take the bad data to a dump sheet and would like to record who selected in case anyone questions why data was removed.

 

[north19701]

http://www.mrexcel.com/board2/viewtopic.php?t=74964&highlight=

I'd suggest Ekim's code in the link to get the login name.

 

[Iridium]

Something Colo wrote a while ago to use as an example:

Option Explicit

Private Declare Function WNetGetUser Lib "mpr.dll" Alias "WNetGetUserA" _
                         (ByVal lpName As String, _
                          ByVal lpUserName As String, _
                          lpnLength As Long) As Long

Private Const NO_ERROR = 0
Private Const ERROR_NOT_CONNECTED = 2250&
Private Const ERROR_MORE_DATA = 234
Private Const ERROR_NO_NETWORK = 1222&
Private Const ERROR_EXTENDED_ERROR = 1208&
Private Const ERROR_NO_NET_OR_BAD_PATH = 1203&

Sub WinUsername()
    Dim strBuf As String, lngUser As Long, strUn As String
    strBuf = Space$(255) '//Clear buffer
    lngUser = WNetGetUser("", strBuf, 255)
    If lngUser = NO_ERROR Then
        strUn = Left(strBuf, InStr(strBuf, vbNullChar) - 1)
        Sheets("Sheet1").Range("A11") = "User Name is  " & strUn
    Else
        Sheets("Sheet1").Range("A11") = "Error :" & lngUser
    End If
End Sub

An alternative: http://j-walk.com/ss/excel/tips/tip94.htm

Or have a search of the board on 'environ("username")' (without the single quotes)
HTH

 

[Smitty]

How about:

Sub UserName()
    Dim CurrentUserName As String
        CurrentUserName = Environ("Username")
    Sheets("Sheet1").Range("A1") = CurrentUserName
End Sub

Hope that helps,

Smitty

 

[Joe C]

Pennysaver was just what I needed. Thanks to all contributers.