Help needed - Button to clear multiple workbooks

[Valleymatt]

Hi guys, hoping you can help on my first post.

I have about 20 different workbooks (one for each staff member) and they each complete confidential data on these every day. The data then feeds in to a master sheet that only I can see. I have added a button to each individual workbook so that it clears all unlocked cells of data and can be re-used the following day. However, I can only clear the workbooks when I'm satisfied that I have gathered all the required information. I then have to go in to each workbook, enable the macro, clear the data, save and exit. This can be very time consuming. Is it possible to add a button to the master sheet that will 'trigger' the clear data button on all the other workbooks? Any help would be greatly appreciated. Thanks.
VM

 

[Logit]

.
.
https://www.rondebruin.nl/win/s3/win010.htm

 

[tonyyy]

Valleymatt,

Welcome to the Board.

The construct for calling a macro in another workbook (assuming the other workbook is open) is:

Application.Run "MacroBook!MacroName"

So essentially you need a loop to open each of the 20 workbooks, call its macro, close the workbook, and repeat with the next workbook.

Cheers,

tonyyy

 

[Logit]

.
.

Option Explicit


Sub LoopAllExcelFilesInFolder()
'PURPOSE: To loop through all Excel files in a user specified folder and perform a set task on them
'SOURCE: www.TheSpreadsheetGuru.com


Dim wb As Workbook
Dim myPath As String
Dim myFile As String
Dim myExtension As String
Dim FldrPicker As FileDialog


'Optimize Macro Speed
  Application.ScreenUpdating = False
  Application.EnableEvents = False
  Application.Calculation = xlCalculationManual


'Retrieve Target Folder Path From User
  Set FldrPicker = Application.FileDialog(msoFileDialogFolderPicker)


    With FldrPicker
      .Title = "Select A Target Folder"
      .AllowMultiSelect = False
        If .Show <> -1 Then GoTo NextCode
        myPath = .SelectedItems(1) & "\"
    End With


'In Case of Cancel
NextCode:
  myPath = myPath
  If myPath = "" Then GoTo ResetSettings


'Target File Extension (must include wildcard "*")
  myExtension = "*.xls*"


'Target Path with Ending Extention
  myFile = Dir(myPath & myExtension)


'Loop through each Excel file in folder
  Do While myFile <> ""
    'Set variable equal to opened workbook
      Set wb = Workbooks.Open(Filename:=myPath & myFile)
    
    'Ensure Workbook has opened before moving on to next line of code
      DoEvents


'////////////////////////////////////////////////////////////////////////////
    
    '-->    Place your macro here to run the macro in the other workbooks.          <---
    '-->    Probably best that the macro would be named the same thing in each      <---
    '-->    of the other workbooks to simplify the coding here.                     <---
    
'////////////////////////////////////////////////////////////////////////////
    'Save and Close Workbook
      wb.Close SaveChanges:=True
      
    'Ensure Workbook has closed before moving on to next line of code
      DoEvents


    'Get next file name
      myFile = Dir
  Loop


'Message Box when tasks are completed
  MsgBox "Task Complete!"


ResetSettings:
  'Reset Macro Optimization Settings
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True


End Sub