if all values in a range are the same, return yes

[prochasska]

Hello,

I have a table in Excel where I want to have a formula which if all values every six cells in a column are equal, returns yes for the six cells and to return no if the values are not equal.
Here is an example.

The formula should return yes, all the cells in column N are the same

column N

Los Angeles

Los Angeles

Los Angeles

Los Angeles

Los Angeles

Los Angeles

<tbody>
</tbody>

The formula should return no, as not all values in the six cells are the same

column N

Los Angeles

Los Angeles

Los Angeles

Barcelona

Barcelona

Rome

<tbody>
</tbody>

I know that a countif function should be incorporated in an if function but I cannot get it right.
The formula returns yes only for the first of six cells if the condition is true and not for the six cells of the range.

I hope someone can help me create a formula which works in this case.

 

[Special-K99]

=IF(COUNTIF(N1:N6,N1)=6,"Yes","No")

There are 6 rows.
If the number of cells that match the first cell is 6 then all cells are the same so output Yes otherwise No.

 

[Scott T]

If it is always 6 cells then this should work

Excel 2010
	A	B	C
1	Los Angeles		Yes
2	Los Angeles
3	Los Angeles
4	Los Angeles
5	Los Angeles
6	Los Angeles
7
8	Los Angeles		No
9	Los Angeles
10	Dallas
11	Los Angeles
12	Los Angeles
13	Los Angeles
Sheet1

Cell Formulas
Range	Formula
C1	=IF(COUNTIF(A1:A6,A1)=6,"Yes","No")
C8	=IF(COUNTIF(A8:A13,A8)=6,"Yes","No")

 

[prochasska]

Thank you. But thi sformula doesn't return "yes" for all the six cells but only for the forst one.
Do you have an idea how to make it return yes for all the six cells?

 

[Special-K99]

This will do it

=IF(COUNTIF(N$1:N$6,N1)=6,"Yes","No")
and copy down for 6 rows.

Though I'm at a loss why you want the same result displayed 6 times.

UPDATE: Hang on, do you mean you want to check each group of 6 rows in the column?
ie rows 1-6 are the same rows 7-12 are the same rows 13-18 are the same etc 19-24, 25-30...

 

[prochasska]

Yes, I want to check each group of 6 rows (1-6, 7-12, etc.).
I want the result displayed because the value in rows 1-6 and 7-12 may be the same but the values in 13-18, 19-24 will not be.
Now imagine with a file of 4,000 and more rows ...

 

[MARZIOTULLIO]

	A​	B​
1​	Los Angeles	yes
2​	Los Angeles	yes
3​	Los Angeles	yes
4​	Los Angeles	yes
5​	Los Angeles	yes
6​	Los Angeles	yes
7​
8​
9​	Los Angeles	no
10​	Los Angeles	no
11​	Dallas	no
12​	Los Angeles	no
13​	Los Angeles	no
14​	Los Angeles	no

<tbody>
</tbody>

b1=IF(AND(A1=$A$1:$A$6),"yes","no") control+shift+enter copy down

b9=IF(AND(A9=$A$9:$A$14),"yes","no") control+shift+enter copy down

 

[Eric W]

This version automatically changes the range for every 6 rows, so you can enter it in B1 and drag down the column as far as needed.

	A	B
1	Los Angeles	Yes
2	Los Angeles	Yes
3	Los Angeles	Yes
4	Los Angeles	Yes
5	Los Angeles	Yes
6	Los Angeles	Yes
7	Los Angeles	No
8	Los Angeles	No
9	Dallas	No
10	Los Angeles	No
11	Los Angeles	No
12	Los Angeles	No
13	San Jose	No
14	San Jose	No
15	San Jose	No
16	Oakland	No
17	San Jose	No
18	San Jose	No

<colgroup><col style="width: 25pxpx"><col><col></colgroup><thead>
</thead><tbody>
</tbody>

Sheet4​

Worksheet Formulas Cell Formula B1 =IF(COUNTIF(OFFSET($A$1,FLOOR(ROW()-1,6),0,6,1),A1)=6,"Yes","No") <thead> </thead><tbody> </tbody>

<tbody>
</tbody>

 

[prochasska]

Thank you so much!
It runs like a clock

 

[Special-K99]

Here's another variation.
Funny how you think of a solution when you're on your way home!

=IF(A1="","",IF(SUMPRODUCT((QUOTIENT(ROW(A$1:A$12000)-1,6)=QUOTIENT(ROW()-1,6))*(A$1:A$12000<>"")*(A$1:A$12000=A1))=6,"Yes","No"))
and copy down