Getting “Error: 91: Object variable or With block variable not set" inside a function. Not sure why. Help!

[ChetShannon]

Hi,
I am getting an “Error: 91: Object variable or With block variable not set” inside a function I am running. Not sure why. My mouseover of the variables being passed to the function shows the values are present. (macro_name, strid, strURL, strfile all present.)

What might be causing this type of error?? Stumped I am!.. .Thanks.. My code for the function below.


Function GetGNPReport(macro_name As String, strid As String, strURL As String, Optional strfile As String) As String
Dim myVars As String
On Error GoTo getout

myHttp.Open "GET", strURL, False
'code failing on this GET statement above and goes to getout: as of tue 130pm error code 91
'strURL= web link removed
' myHttp.SetRequestHeader "User-Agent", macro_name & " " & strid

myHttp.Send
myHttp.waitForResponse

If myHttp.Status <> "200" Then
GetGNPReport = "Error: HTTP RESPONSE " & myHttp.Status & " - " & myHttp.StatusText
Exit Function
End If

If strfile <> "" Then
Dim mystream As TextStream
Dim myfsobj As New FileSystemObject
Set mystream = myfsobj.OpenTextFile(strfile, ForWriting, True)
mystream.Write myHttp.ResponseText
End If

GetGNPReport = myHttp.ResponseText

getout:
If Err.Number <> 0 Then
GetGNPReport = "Error: " & Err.Number & ": " & Err.Description
End If
End Function

 

[John_w]

Where is myHttp declared (Dim) and defined (Set)?

 

[ChetShannon]

I have myHttp as a "Public myHttp As Object" above this function in a standalone section of the code. I don't have a SET statement for myHttp though. Maybe I need that?...

 

[John_w]

You definitely need to Set myHttp somewhere. As you've declared myHttp as a global variable you could define it in any procedure which (eventually) calls GetGNPReport:

    If myHttp Is Nothing Then Set myHttp = CreateObject("MSXML2.XMLHTTP")

If myHttp is only used by GetGNPReport then I would delete the Public declaration and put this inside GetGNPReport:

    Static myHttp As Object
    If myHttp Is Nothing Then Set myHttp = CreateObject("MSXML2.XMLHTTP")

 

[ChetShannon]

You definitely need to Set myHttp somewhere. As you've declared myHttp as a global variable you could define it in any procedure which (eventually) calls GetGNPReport:

    If myHttp Is Nothing Then Set myHttp = CreateObject("MSXML2.XMLHTTP")

If myHttp is only used by GetGNPReport then I would delete the Public declaration and put this inside GetGNPReport:

    Static myHttp As Object
    If myHttp Is Nothing Then Set myHttp = CreateObject("MSXML2.XMLHTTP")

Thank you!